dev-libs/libdex: Version bump to 0.4.3

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/34834
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

dev-libs/libdex/Manifest

@@ -1,3 +1,4 @@
 DIST libdex-0.2.0.tar.xz 91648 BLAKE2B 258193b29082024cce30d5e20903f1ba6a3c8e566652d341845178797126796fcc1cf628636de02ba9776cb9d8ff5d38c24f10f269fcd9acbc0cdbb1c0918d8b SHA512 db54fa974af97e59e7a21c19be73db8fec6565377ce313a3532435845d3571216d6617f9a8db500019390d85677ca6f30be3f9a36c60240c8130ae0834826a65
 DIST libdex-0.4.0.tar.xz 95468 BLAKE2B d45760dd826835cb2e5bffe1a69b7fcfb4b20fcfb55c119fc3175ae80e2c9b6d34d3df5c653075ed2832183f2c76b3dcaf2509977fe9b79f1dabbb59a3301602 SHA512 806d0c6cb7fe9cd0bdf4e85cf93b9bc67ee11bce0e18ba6c5eb8b075e2a3d22359cf58374b6f07e558f8595b24093c052f4e05763104163b46bec0371efbb295
 DIST libdex-0.4.1.tar.xz 95492 BLAKE2B 73e660cd5876f41f7e02bdb35cc460888eaf40a62c7431e7fcd2337a2eb953f975a8f6719c0726672be71ab507561413257c140a31cfdcab09491d4228362796 SHA512 80a80c6fcf936da903a64339dff1d6f802f028bfd6e2815bf3b2a3ac6bd0e9fafe3f81b66dd1ee0a6bbd6303cc31fc73b528829e587142a7d269b1b98377ca25
+DIST libdex-0.4.3.tar.xz 96820 BLAKE2B 51f6c9a209d8ff19d7e97f4d8cbc9065739f08c555712076c9b6f4d345d56522f31afa1b8dffe8da2cfc128d368d7dc5f6a93757f0fe5cfd0a55de17587d776e SHA512 26691373d560d20cefa3a23e31677259b234cdf623b17b8fb2b6976b03768e86e458d2670aa3b260638b595994f278240e972bf3ff5b765013fb6d3114f46cef

dev-libs/libdex/libdex-0.4.3.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org linux-info meson vala
+
+DESCRIPTION="Deferred Execution library for GNOME and GTK"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdex"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="eventfd gtk-doc +introspection liburing sysprof test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	liburing? ( >=sys-libs/liburing-0.7:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+pkg_setup() {
+	if use eventfd && linux_config_exists; then
+		if ! linux_chkconfig_present EVENTFD ; then
+			ewarn "CONFIG_EVENTFD must be enabled for USE=eventfd"
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dexamples=false
+		$(meson_use vala vapi)
+		$(meson_feature introspection)
+		$(meson_use sysprof)
+		$(meson_use test tests)
+		$(meson_feature liburing)
+		$(meson_feature eventfd)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}

dev-libs/libdex/metadata.xml

@@ -17,6 +17,8 @@
     <remote-id type="gnome-gitlab">GNOME/libdex</remote-id>
   </upstream>
   <use>
+    <flag name="eventfd">Allow use of eventfd</flag>
+    <flag name="liburing">Allow use of liburing (io_uring)<pkg>sys-libs/liburing</pkg></flag>
     <flag name="sysprof">Enable profiling data capture support using <pkg>dev-util/sysprof-capture</pkg></flag>
   </use>
 </pkgmetadata>