media-plugins/grilo-plugins: bump to 0.3.7

Package-Manager: Portage-2.3.43, Repoman-2.3.10

media-plugins/grilo-plugins/Manifest

@@ -1,2 +1,3 @@
 DIST grilo-plugins-0.2.17.tar.xz 1036308 BLAKE2B c83de5b251c030c71164310f6240652ffc86efa46a057bc750ee242c7cc2ff91a9c28ec6a847783cf7fd2df068cba0dad6f10521db82c7080a466c63aacb4c03 SHA512 f556ae6e72c82ce74cc8902f7b4ae27f51060c3b06230989b36ce4498f93894c723809c1f08fc8edfabd892fc303eb0523f21ea72649f644c7eb421b62773140
 DIST grilo-plugins-0.3.5.tar.xz 1881080 BLAKE2B 06f06fe47cf6fb374d3d398e113a2d851c46e390011f2ef8c04a9b658bd04eea5f0c17ad4e89f7cd922ac0a24efe94f30db65697d4b71fab512eaf71c8ef936c SHA512 3420b18d5d938559b75ae41199a6a79dfa5a8a43d2b29631f7cb03c28df569627be610a4087514240c3413e476fa76def3ee7a1b065b5104679b788b633a5b0e
+DIST grilo-plugins-0.3.7.tar.xz 1892848 BLAKE2B 9894a01dc555f20c3119208e2ee875898c918f8d81e36571a777f7f1776c284d5fa5b4ac9126a352dc812b0f5ba9c15e0e81a2381ef9cb636afb66e272a77cec SHA512 9e69835b3b8f6e2974d799480e2c8c55a084d2089ead6b37112a8c3c79b6bd2142b8fd66952493b7118e09eb5070789408b59bd28784bd9f6bf5ea5a7bc5695d

media-plugins/grilo-plugins/grilo-plugins-0.3.7.ebuild

@@ -0,0 +1,132 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit gnome2 python-any-r1
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="daap dvd examples chromaprint flickr freebox gnome-online-accounts lua subtitles test thetvdb tracker upnp-av vimeo +youtube"
+
+# Bump gom requirement to avoid segfaults
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=media-libs/grilo-0.3.6:${SLOT}=[network,playlist]
+	media-libs/libmediaart:2.0
+	>=dev-libs/gom-0.3.2
+
+	dev-libs/gmime:3.0
+	dev-libs/json-glib
+	dev-libs/libxml2:2
+	dev-db/sqlite:3
+
+	chromaprint? ( media-plugins/gst-plugins-chromaprint:1.0 )
+	daap? ( >=net-libs/libdmapsharing-2.9.12:3.0 )
+	dvd? ( >=dev-libs/totem-pl-parser-3.4.1 )
+	flickr? ( net-libs/liboauth )
+	freebox? ( net-dns/avahi )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.17.91:= )
+	lua? (
+		>=dev-lang/lua-5.3
+		app-arch/libarchive
+		dev-libs/libxml2:2
+		>=dev-libs/totem-pl-parser-3.4.1 )
+	subtitles? ( net-libs/libsoup:2.4 )
+	thetvdb? (
+		app-arch/libarchive
+		dev-libs/libxml2 )
+	tracker? ( >=app-misc/tracker-0.10.5:= )
+	youtube? (
+		>=dev-libs/libgdata-0.9.1:=
+		>=dev-libs/totem-pl-parser-3.4.1 )
+	upnp-av? (
+		net-libs/libsoup:2.4
+		net-libs/dleyna-connector-dbus
+		net-misc/dleyna-server )
+	vimeo? (
+		>=dev-libs/totem-pl-parser-3.4.1 )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.5
+	app-text/yelp-tools
+	>=dev-util/gdbus-codegen-2.44
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+	lua? ( dev-util/gperf )
+	upnp-av? ( test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]') ) )
+"
+
+python_check_deps() {
+	use upnp-av && use test && has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use upnp-av && use test && python-any-r1_pkg_setup
+}
+
+src_prepare () {
+	gnome2_src_prepare
+	sed -e "s:GETTEXT_PACKAGE=grilo-plugins$:GETTEXT_PACKAGE=grilo-plugins-${SLOT}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+}
+
+# FIXME: some unittests required python-dbusmock
+src_configure() {
+	# --enable-debug only changes CFLAGS, useless for us
+	# Plugins
+	# shoutcast seems to be broken
+	gnome2_src_configure \
+		--disable-static \
+		--disable-debug \
+		--disable-uninstalled \
+		--enable-bookmarks \
+		--enable-filesystem \
+		--enable-gravatar \
+		--enable-jamendo \
+		--enable-local-metadata \
+		--enable-magnatune \
+		--enable-metadata-store \
+		--enable-podcasts \
+		--enable-raitv \
+		--disable-shoutcast \
+		--enable-tmdb \
+		$(use_enable chromaprint) \
+		$(use_enable daap dmap) \
+		$(use_enable dvd optical-media) \
+		$(use_enable flickr) \
+		$(use_enable freebox) \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable lua lua-factory) \
+		$(use_enable subtitles opensubtitles) \
+		$(use_enable thetvdb) \
+		$(use_enable tracker) \
+		$(use_enable upnp-av dleyna) \
+		$(use_enable vimeo) \
+		$(use_enable youtube)
+}
+
+src_install() {
+	if use examples; then
+		docinto examples
+		doins help/examples/*.c
+	fi
+
+	gnome2_src_install \
+		DOC_MODULE_VERSION=${SLOT%/*} \
+		HELP_ID="grilo-plugins-${SLOT%/*}" \
+		HELP_MEDIA=""
+
+	# The above doesn't work and collides with 0.2 slot
+	mv "${ED}"/usr/share/help/C/examples/example-tmdb{,-0.3}.c || die
+	mv "${ED}"/usr/share/help/C/grilo-plugins/legal{,-0.3}.xml || die
+	mv "${ED}"/usr/share/help/C/grilo-plugins/grilo-plugins{,-0.3}.xml || die
+}