dev-python/oslo-config: Bump to 10.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/oslo-config/Manifest

@@ -1 +1,2 @@
 DIST oslo_config-10.1.0.tar.gz 165089 BLAKE2B 253e10e6d949fcd773a0c394a8a8d6a45e59e63c20f9b596eef99868c73422e5eb5b7a57c9e57fe3451511f8c719fcc36abf6b02eeee85c7f2b9d57a370f14ba SHA512 319be3b18ddc3a1f34bfd72fc39790e3916ddb9fd86f76f85b10d5d544bcd48619900aa60bd6f9d564be184272f665222eb102e271f6e4832c5725be99769d75
+DIST oslo_config-10.2.0.tar.gz 163256 BLAKE2B c9521c5dfa3f8103c53de47cfa93a579e0619ec37f1f1692c3ed92cb114fc7d339b7acf723dc3d190826767f77f790f2b0c3c82d61b720080e617143e6527d2a SHA512 6673dfffb763fbc3baae574928ad75a02a6e490ad22f1e297c78c4c2e8d50f58937f64af79e758f6795285545c4176bac12c81d2cbecfd754717d15567f6b684

dev-python/oslo-config/oslo-config-10.2.0.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Configuration API"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.config/
+	https://github.com/openstack/oslo.config/
+	https://pypi.org/project/oslo.config/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-5.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.8.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# broken by some dep upgrade
+	sed -i oslo_config/tests/test_cfg.py \
+		-e '/DeprecationWarningTestsNoOsloLog/,$d' \
+		-e 's/test_sub_command_multiple/_&/' || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x COLUMNS=80
+	eunittest -b
+}