dev-python/dask-expr: New package, v1.0.1

New dependency of dev-python/dask.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/dask-expr/Manifest

@@ -0,0 +1 @@
+DIST dask-expr-1.0.1.gh.tar.gz 233067 BLAKE2B 8638c7f457aa7decdad71de95f4a1ebc2af32781a28ef6e76fc4f59cd2c417ce3f005e77b42553625e045c44c9574686a549c48a44acb7939da467bb5ef603d1 SHA512 6de85ee49c55f36e20b75c4df48b757e278e6e4dba85ee30ecf33644c5533e0424c55de03b4d37beef33d00bd52000f7d2ddbc3d762d31e8999e2657eea1778d

dev-python/dask-expr/dask-expr-1.0.1.ebuild

@@ -0,0 +1,56 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="High Level Expressions for Dask"
+HOMEPAGE="
+	https://github.com/dask/dask-expr/
+	https://pypi.org/project/dask-expr/
+"
+# pypi tarball removes tests, as of 1.0.1
+SRC_URI="
+	https://github.com/dask/dask-expr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/dask-2024.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyarrow-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pandas-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin
+	sed -i -e '/dask/s:==:>=:' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires distributed
+		'dask_expr/tests/test_shuffle.py::test_respect_context_shuffle[shuffle]'
+	)
+	local EPYTEST_IGNORE=(
+		# requires distributed
+		dask_expr/io/tests/test_parquet.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}

dev-python/dask-expr/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">dask/dask-expr</remote-id>
+		<remote-id type="pypi">dask-expr</remote-id>
+	</upstream>
+</pkgmetadata>