app-text/pdf2djvu: version bump to 0.9.11

Closes: https://bugs.gentoo.org/656502
Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Matthias Maier <tamiko@gentoo.org>

app-text/pdf2djvu/Manifest

@@ -1 +1,2 @@
+DIST pdf2djvu-0.9.11.tar.xz 291356 BLAKE2B 726d9132c43c7dabdecf1e6174a3f2627db7f6981b3ba1f280ea131272ea0fef38acdaaa0f78ab0c883dd2cd046017edac46bb10d91e10668a6e480322e465fb SHA512 7b47ff4cd3a49f3fa1fec08490a192725899307d9c2a75a65a21d36abcece2f308e56161ec4c4f77f32fbdedcc167520657cad2b06cf178335f7e2169b7ada82
 DIST pdf2djvu-0.9.8.tar.xz 268976 BLAKE2B 318ef4fd5677056d2404d769bf54911c9474d6f0f839ef472e121375ee268db31ddaaad2b8ed791ef093d6cb1c665f6431619918ee852e479b4a11a3d7ae0e23 SHA512 5f5330d3d15808b5b6233a15a984d0ebf28619cfb50807a20c8992fed68d17f73d1edd62b1ad7cd3a09d526f6c9f0827e2c5e03d6d7c8ad92c1f106755025f5e

app-text/pdf2djvu/pdf2djvu-0.9.11.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-any-r1 toolchain-funcs flag-o-matic
+
+DESCRIPTION="A tool to create DjVu files from PDF files"
+HOMEPAGE="http://jwilk.net/software/pdf2djvu"
+SRC_URI="https://github.com/jwilk/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+graphicsmagick nls openmp test"
+
+RDEPEND="
+	>=app-text/djvu-3.5.21:=
+	>=app-text/poppler-0.16.7:=
+	dev-libs/libxml2:=
+	dev-libs/libxslt:=
+	graphicsmagick? ( media-gfx/graphicsmagick:= )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/pstreams
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/nose[${PYTHON_USEDEP}]')
+	)
+"
+
+REQUIRED_USE="test? ( graphicsmagick ${PYTHON_REQUIRED_USE} )"
+
+DOCS=(
+	doc/{changelog,credits,djvudigital,README}
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# bug 626874, poppler headers require C++11
+	append-cxxflags -std=c++11
+	default
+}
+
+src_configure() {
+	local openmp=--disable-openmp
+	use openmp && tc-has-openmp && openmp=--enable-openmp
+
+	econf \
+		${openmp} \
+		$(use_enable nls) \
+		$(use_with graphicsmagick)
+}