dev-python/livereload: Bump to 2.7.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/livereload/Manifest

@@ -1 +1,2 @@
 DIST python-livereload-2.7.0.gh.tar.gz 26138 BLAKE2B 4cb2fd5352cbb68f09c914000e37b8305d66c9735e232e5eccad3ea1016ffc6d3da0846ebce048385f6606ceaa176b8df77461d9a0ca939a2f65d089cec9c3e9 SHA512 676f50b9300e1582177493cef24f4e2b10a4e385d0de780bf9161dee66e3063420338021464477c8079bffd0e4690a4b0d15c71025ebf1959addbaa6e69fa8bb
+DIST python-livereload-2.7.1.gh.tar.gz 26793 BLAKE2B e06bc364c660189d51b9553614e37a70fabeccf16d9af15763b398936e4889e6d7ed760145e424da22da3ff4a0b53cbcc7de8e226a6938025ee5d8dfcfd54410 SHA512 a0c5a316ad5d34518b6ca44cddff51ba45d60a8ba24de767e791aa529e4ab22accf15916321fea755e67f4fd0aecb1e0ed840142662c27c8eaa6cad5dc2a7399

dev-python/livereload/livereload-2.7.1.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+MY_P=python-livereload-${PV}
+DESCRIPTION="livereload server in Python"
+HOMEPAGE="
+	https://github.com/lepture/python-livereload/
+	https://pypi.org/project/livereload/
+"
+SRC_URI="
+	https://github.com/lepture/python-livereload/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/furo \
+	dev-python/myst-parser \
+	dev-python/sphinxcontrib-programoutput
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	# tests/test_watcher.py::TestWatcher::test_watch_multiple_dirs
+	# is extremely flaky
+	epytest -p rerunfailures --reruns=10
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}