xfce-base/xfce4-panel: Bump to 4.14.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.12.2.tar.bz2 1167175 BLAKE2B 09d16c58bb2d78242069fc2191009af6bb737fd6571f7d9ceef4b2b2dc0f0be6fcdad17aa588f69573b9d7f62ca0c54ec712bd467ff793b6952ede733889136b SHA512 b455e28ecbd9e2fc152e1132a806307597157605fef19c61091fce90984b2eded2c0b691d1fa2475c218c9d0b12103e348e648a32d3e8d0aa9ca210b7ae36a9e
 DIST xfce4-panel-4.14.0.tar.bz2 1291792 BLAKE2B 16cc35eba39440fd03ff0e55ed1750f52291734e73dc3358f9ea4c819af328205db3e3b62f823f1ac116faa2db162df0ea4709c7f573f1b867a531970158de35 SHA512 47a91b9ce7277612848fd1b48f9c0d6e5169cd0405a99863d685e7a9c5aa3cb8f30694ecdbf657e0f289278dc0c003c8b0784ff03e41e82c1886847ad292972f
+DIST xfce4-panel-4.14.1.tar.bz2 1294087 BLAKE2B d88100d068348aab32f7a133ca98e17c1586f3d6c5ffcb53493e953930108d4d1ebd0972d84c4bd077ab58c4a3ae34303682084daff4e34a168c5c2f981597bf SHA512 1c86362489677f2e04cf3b98dbc1a80b4998335c00a47d256e741446f00437ad04539041648848eca1f45fa1fa70974ca6cf65cb7f762a79a46c16484557e400

xfce-base/xfce4-panel/xfce4-panel-4.14.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+gtk2 introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!gtk2? ( test )"
+
+RDEPEND=">=dev-libs/glib-2.42
+	>=x11-libs/cairo-1
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libwnck:3
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-0.5:=
+	>=xfce-base/libxfce4ui-4.13:=
+	>=xfce-base/libxfce4util-4.13:=[introspection?]
+	>=xfce-base/xfconf-4.13:=
+	gtk2? ( >=x11-libs/gtk+-2.20:2 )
+	introspection? ( dev-libs/gobject-introspection:= )"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable gtk2)
+		$(use_enable introspection)
+		$(use_enable vala)
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}