mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
net-misc/remmina: add 1.4.26
Signed-off-by: Ben Kohler <bkohler@gentoo.org>
This commit is contained in:
@@ -1,3 +1,4 @@
|
||||
DIST Remmina-v1.4.23.tar.gz 3280050 BLAKE2B b62789dba4a4f0a0a12f4cc1da68431b0c386b618f3bf7babe8946cba3753bdfd8799731a254c18cf58e8a43efe6980d638adc9512303dfb229c5b340d957402 SHA512 151baead9c8e8051f6da2139691aa5644ccdd5752e1dd1be572b72fab01773caf261bfe44ebebc8524a36b447ee335275e6522bd2b6b65d4f0a790c92bd291d4
|
||||
DIST Remmina-v1.4.24.tar.gz 3375550 BLAKE2B 3ce777e3493c51915928ae63072c3df2123426563b514aa0cbde076084045e0e08c41fd363244db9dea247ca265486cad2184f7996cddcea941e983371d6af4e SHA512 39fecb82cedcd08720f800a69f778125811a141a152e88e8d657f082c5efcc4525483fb8374712db48743f9a0c2222e2312a9b3ecf5f043761d029edda86609d
|
||||
DIST Remmina-v1.4.25.tar.gz 3404247 BLAKE2B 59798362b33780041975f8af6c11b14a36876badeaed341f4600e9e920ec2b2ca78f33ddc69bb52608fc45488aefacf6c9ec9751369a4b5c23507519494180c4 SHA512 2409d316894a423de487c264861bda782bac365d13eb77f965863173072da85d228047ca0624bc7664cf6c1a5144598895371a56e37a1cc90df426d19b5719a8
|
||||
DIST Remmina-v1.4.26.tar.gz 3451611 BLAKE2B 574510c7c2deed73887b4dec2b0b7036f5e4bfccb8c0229f9bcbca934896837a758d51e95965549643b44cedb66b57cdf9b7e5500790825951cc98d6846e8687 SHA512 fe81f3878017b82208255cc757d8897868cb810e44dd7d8dc88c8d371f96cec80936aaf86fd216568fba91401e13463bf3b278789b7c8839403f8c294cc049fc
|
||||
|
||||
@@ -0,0 +1,104 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit cmake optfeature xdg
|
||||
|
||||
MY_P="${PN^}-v${PV}"
|
||||
|
||||
DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
|
||||
HOMEPAGE="https://remmina.org/"
|
||||
SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2+-with-openssl-exception"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="+appindicator crypt cups examples gnome-keyring gvnc kwallet nls spice ssh rdp telemetry vnc webkit x2go zeroconf"
|
||||
|
||||
COMMON_DEPEND="
|
||||
dev-libs/glib:2
|
||||
dev-libs/json-glib
|
||||
dev-libs/libpcre2
|
||||
dev-libs/libsodium:=
|
||||
dev-libs/openssl:0=
|
||||
net-libs/libsoup:2.4
|
||||
x11-libs/gdk-pixbuf
|
||||
x11-libs/gtk+:3
|
||||
x11-libs/libX11
|
||||
x11-libs/libxkbfile
|
||||
appindicator? ( dev-libs/libappindicator:3 )
|
||||
crypt? ( dev-libs/libgcrypt:0= )
|
||||
gnome-keyring? ( app-crypt/libsecret )
|
||||
gvnc? ( net-libs/gtk-vnc )
|
||||
kwallet? ( kde-frameworks/kwallet )
|
||||
rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
|
||||
<net-misc/freerdp-3[X]
|
||||
cups? ( net-print/cups:= ) )
|
||||
spice? ( net-misc/spice-gtk[gtk3] )
|
||||
ssh? ( net-libs/libssh:0=[sftp]
|
||||
x11-libs/vte:2.91 )
|
||||
vnc? ( net-libs/libvncserver[jpeg] )
|
||||
webkit? ( net-libs/webkit-gtk:4 )
|
||||
x2go? ( net-misc/pyhoca-cli )
|
||||
zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
|
||||
"
|
||||
|
||||
DEPEND="
|
||||
${COMMON_DEPEND}
|
||||
spice? ( app-emulation/spice-protocol )
|
||||
"
|
||||
|
||||
BDEPEND="
|
||||
dev-util/intltool
|
||||
virtual/pkgconfig
|
||||
nls? ( sys-devel/gettext )
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
${COMMON_DEPEND}
|
||||
virtual/freedesktop-icon-theme
|
||||
"
|
||||
|
||||
DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
src_prepare() {
|
||||
xdg_environment_reset
|
||||
cmake_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
|
||||
-DWITH_AVAHI=$(usex zeroconf)
|
||||
-DWITH_CUPS=$(usex cups)
|
||||
-DWITH_EXAMPLES=$(usex examples)
|
||||
-DWITH_FREERDP=$(usex rdp)
|
||||
-DWITH_FREERDP3=OFF
|
||||
-DWITH_GCRYPT=$(usex crypt)
|
||||
-DWITH_GETTEXT=$(usex nls)
|
||||
-DWITH_ICON_CACHE=OFF
|
||||
-DWITH_KF5WALLET=$(usex kwallet)
|
||||
-DWITH_LIBSECRET=$(usex gnome-keyring)
|
||||
-DWITH_LIBSSH=$(usex ssh)
|
||||
-DWITH_LIBVNCSERVER=$(usex vnc)
|
||||
-DWITH_NEWS=$(usex telemetry)
|
||||
-DWITH_SPICE=$(usex spice)
|
||||
-DWITH_TRANSLATIONS=$(usex nls)
|
||||
-DWITH_UPDATE_DESKTOP_DB=OFF
|
||||
-DWITH_VTE=$(usex ssh)
|
||||
-DWITH_WWW=$(usex webkit)
|
||||
-DWITH_X2GO=$(usex x2go)
|
||||
# when this feature is stable, add python eclass usage to optionally enable
|
||||
-DWITH_PYTHON=OFF
|
||||
)
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
|
||||
}
|
||||
Reference in New Issue
Block a user