mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
kde-frameworks/extra-cmake-modules: 5.77.0 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST extra-cmake-modules-5.74.0.tar.xz 344588 BLAKE2B 00724160628ee9cb628b5f3f3b119908b9f0b135f4c98f5f2ac0b2d707abb0fd8775cb87ff7bad152e2010647b64222c57ee8a042d89c5649bb7d27d5f3b3839 SHA512 5d4f612758bda73d8327cc582bda3550807de90e1b729d24a59ac7e70db127da208a53590f48cda9775f2be6e22a7db47958e3f01577b4baf0b8ef86672579a1
|
||||
DIST extra-cmake-modules-5.76.0.tar.xz 349944 BLAKE2B a287da2445e0e6a66b9a316b4e2f0715454919074c0e9b476e1a7a1a5805d5ec934f4fd8b87d3615129863531b879923d3934d716e1a9f53efbcbf3c4da405ad SHA512 7d3f63dd3ca07678fc3be6c382fec790ef1c189be36125b4f63cf1ea07ffa10ba47e82aa1ef3c6baab03372ce8ee6fbe04bb95fe2f6b9025d2c222936e5b1eb6
|
||||
DIST extra-cmake-modules-5.77.0.tar.xz 353784 BLAKE2B 08f70ab68fa1de0a8014fffb5a5f638fc49ea4d17a68de4a2061746bc95218235e18066d865ed12c746deb2212f61299675fefc4c89b2ed9d48e675925904f5e SHA512 0581b3f8f17ad452140a68e9d1b14014235523ecc2df2b6a8e6a6b3cac99a1b58470b8d31ae2eb695c1e5357d4c5ff26d656bf2f4ede7aba824eaed1e38a3a95
|
||||
|
||||
@@ -0,0 +1,77 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{7,8,9} )
|
||||
QTMIN=5.15.1
|
||||
inherit cmake kde.org python-any-r1
|
||||
|
||||
DESCRIPTION="Extra modules and scripts for CMake"
|
||||
HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
|
||||
|
||||
LICENSE="BSD"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
|
||||
IUSE="doc test"
|
||||
|
||||
BDEPEND="
|
||||
doc? (
|
||||
${PYTHON_DEPS}
|
||||
$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
|
||||
>=dev-qt/qthelp-${QTMIN}:5
|
||||
)
|
||||
test? (
|
||||
>=dev-qt/linguist-tools-${QTMIN}:5
|
||||
>=dev-qt/qtcore-${QTMIN}:5
|
||||
)
|
||||
"
|
||||
RDEPEND="
|
||||
app-arch/libarchive[bzip2]
|
||||
"
|
||||
|
||||
RESTRICT+=" !test? ( test )"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
|
||||
"${FILESDIR}/${PN}-5.72.0-skip-ecm_add_test-early.patch"
|
||||
"${FILESDIR}/${PN}-5.74.0-disable-qmlplugindump.patch"
|
||||
)
|
||||
|
||||
python_check_deps() {
|
||||
has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
use doc && python-any-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
cmake_src_prepare
|
||||
# Requires PyQt5, bug #680256
|
||||
sed -i -e "/^if(NOT SIP_Qt5Core_Mod_FILE)/s/NOT SIP_Qt5Core_Mod_FILE/TRUE/" \
|
||||
tests/CMakeLists.txt || die "failed to disable GenerateSipBindings tests"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
|
||||
-DBUILD_QTHELP_DOCS=$(usex doc)
|
||||
-DBUILD_HTML_DOCS=$(usex doc)
|
||||
-DBUILD_MAN_DOCS=$(usex doc)
|
||||
-DBUILD_TESTING=$(usex test)
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# ECMToolchainAndroidTest passes but then breaks src_install
|
||||
# ECMPoQmToolsTest is broken, bug #627806
|
||||
# possible race condition with multiple jobs, bug #701854
|
||||
local myctestargs=(
|
||||
-j1
|
||||
-E "(ECMToolchainAndroidTest|ECMPoQmToolsTest)"
|
||||
)
|
||||
|
||||
cmake_src_test
|
||||
}
|
||||
Reference in New Issue
Block a user