mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 10:17:08 -08:00
xfce-base/xfce4-power-manager: Bump to 4.20.1
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST xfce4-power-manager-4.20.0.tar.bz2 1523787 BLAKE2B 9df4b976665ee9363b68218ccadeddfba2b79f4446614a16617511c155aa761dac29003f5460b01c98bf27f7845cbf62c5434a521d93f9fc954964c0c9c48657 SHA512 e61762b4ff374562fa3d70b1eb7c9928a1a7197df5b597763adf16435183fd693307267f37f0eb7dd08b573664a397d2fd22674b5db7e07ee9302089772ff6e7
|
||||
DIST xfce4-power-manager-4.20.1.tar.bz2 1536339 BLAKE2B f8b5357bef3f486dd13328f185856f74a855d7c519947e31b4c2d32d06a401738d97f8fd8c3129ca7da9d3972912f5d5764307e714d0b1b249177f7a73d492b3 SHA512 fd73e989856b3a69ab654a95d382523fc404c533b6b51b9194a28686008a7dd9fb5b8cc0b382127eea68a5c1809e8ad61bc0756585c1c2df3a569fd94024c374
|
||||
DIST xfce4-power-manager-4.21.1.tar.xz 628104 BLAKE2B fe7b8416c1edc3946c9510e5b094c88accbc51c1e68e73ad79282aaf7acce6f504dfaf9d1775a03ca3a297117436a6461f4cea3e690863d07129f08171ca64bf SHA512 cf10c7d24c6d51274c7e6a170770678ab3a27d9d407bd5706d70d28f148627e4d90559aeae91d7d5493d994aaabbf5e8bf66cb4da358be18ce806bb44b9be85b
|
||||
|
||||
@@ -0,0 +1,85 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit xdg-utils
|
||||
|
||||
DESCRIPTION="Power manager for the Xfce desktop environment"
|
||||
HOMEPAGE="
|
||||
https://docs.xfce.org/xfce/xfce4-power-manager/start
|
||||
https://gitlab.xfce.org/xfce/xfce4-power-manager/
|
||||
"
|
||||
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
|
||||
|
||||
LICENSE="GPL-2+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="+panel-plugin policykit wayland X"
|
||||
REQUIRED_USE="|| ( wayland X )"
|
||||
|
||||
DEPEND="
|
||||
>=dev-libs/glib-2.72.0
|
||||
>=sys-power/upower-0.99.10
|
||||
>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
|
||||
>=x11-libs/libnotify-0.7.0
|
||||
>=xfce-base/xfconf-4.12:=
|
||||
>=xfce-base/libxfce4ui-4.18.4:=[gtk3(+)]
|
||||
>=xfce-base/libxfce4util-4.19.2:=
|
||||
panel-plugin? ( >=xfce-base/xfce4-panel-4.14.0:= )
|
||||
policykit? ( >=sys-auth/polkit-0.102 )
|
||||
wayland? (
|
||||
>=dev-libs/wayland-1.20
|
||||
)
|
||||
X? (
|
||||
>=x11-libs/libX11-1.6.7
|
||||
>=x11-libs/libXrandr-1.5.0
|
||||
>=x11-libs/libXext-1.0.0
|
||||
x11-libs/libXtst
|
||||
)
|
||||
"
|
||||
RDEPEND="
|
||||
${DEPEND}
|
||||
"
|
||||
DEPEND+="
|
||||
x11-base/xorg-proto
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-util/gdbus-codegen-2.80.5-r1
|
||||
>=sys-devel/gettext-0.19.8
|
||||
virtual/pkgconfig
|
||||
wayland? (
|
||||
>=dev-libs/wayland-protocols-1.25
|
||||
>=dev-util/wayland-scanner-1.20
|
||||
)
|
||||
"
|
||||
|
||||
src_configure() {
|
||||
local myconf=(
|
||||
$(use_enable policykit polkit)
|
||||
$(use_enable panel-plugin xfce4panel)
|
||||
$(use_enable wayland)
|
||||
$(use_enable X x11)
|
||||
)
|
||||
|
||||
econf "${myconf[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
find "${D}" -name '*.la' -delete || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_icon_cache_update
|
||||
|
||||
if ! has_version sys-apps/systemd && ! has_version sys-auth/elogind
|
||||
then
|
||||
elog "Suspend/hibernate support requires a logind provider installed"
|
||||
elog "(sys-apps/systemd or sys-auth/elogind)"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_icon_cache_update
|
||||
}
|
||||
Reference in New Issue
Block a user