games-rpg/the-royal-trap: New package

Package-Manager: Portage-2.3.68, Repoman-2.3.13
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

games-rpg/the-royal-trap/Manifest

@@ -0,0 +1 @@
+DIST The_Royal_Trap_HD_1.2-linux-x86.tar 193616345 BLAKE2B f43eb162abd077b1b2dde85012652704049c18830d0e8eb5ee4aa60b05d4b123b0fe9388aec70154b0d6e8d6a89e12fba06aacf50d5026d2391e6ad90af3d5ba SHA512 d6c0172a35e36fc6e42f1c9827e99f814cd9084a2d94042b9fd2b9a0ffd4ac1adb7c898a6579b856cfde548073b1d34a49fb6ba80d4a6c6bce682673094eff0d

games-rpg/the-royal-trap/metadata.xml

@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<longdescription>
+		Madeleine Valois is a prince's companion. Her job is to guide
+		and advise him, to make him look good so that he can land a
+		royal bride. It is her responsibility to keep him out of
+		trouble - not to let him walk blindly into a political
+		minefield, not to let him get arrested for a crime he didn't
+		commit, and definitely not to let him fall in love with her.
+
+		Unfortunately, events are not going according to plan...
+	</longdescription>
+</pkgmetadata>

games-rpg/the-royal-trap/the-royal-trap-1.2.ebuild

@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils xdg-utils
+
+RENPY_SLOT="6.99"
+MY_PN="The Royal Trap"
+
+DESCRIPTION="Visual novel where you help a prince choose his royal bride"
+HOMEPAGE="https://www.hanakogames.com/royaltrap.shtml"
+SRC_URI="${MY_PN// /_}_HD_${PV}-linux-x86.tar"
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="bindist fetch"
+
+RDEPEND="games-engines/renpy:${RENPY_SLOT}"
+
+S="${WORKDIR}/${MY_PN} HD ${PV}-linux-x86"
+
+pkg_nofetch() {
+	einfo "If you have ${SRC_URI} as distributed by Humble Bundle then move"
+	einfo "it to your distfiles directory. If you have some other version then"
+	einfo "please contact the Gentoo Games team."
+}
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins -r game/*
+
+	make_wrapper ${PN} "renpy-${RENPY_SLOT} '${EPREFIX}/usr/share/${PN}'"
+	make_desktop_entry ${PN} "${MY_PN}" applications-games
+
+	docinto html
+	dodoc README.html
+}
+
+pkg_postinst() { xdg_icon_cache_update; }
+pkg_postrm() { xdg_icon_cache_update; }