mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-05 12:38:09 -07:00
app-office/gnucash: Bump to 3.1
Package-Manager: Portage-2.3.24, Repoman-2.3.6
This commit is contained in:
Aaron W. Swenson
@@ -2,4 +2,5 @@ DIST gnucash-2.7.4.tar.bz2 13364512 BLAKE2B 0a552efe5a4f024517c054516eb25b51abb2
|
||||
DIST gnucash-2.7.5.tar.bz2 13330271 BLAKE2B e06328050a2dd8e80e224cf13f51c1c7151e73f9a1c9f14581f33bfcf8bf07b273962620b7281637101eab8c5eff67a3e5e8e34d81f0c8d263ac33bf6d1eb40c SHA512 68cd6e6f61a43b8837e9efe693d22f62ebe10a8bb7d593814fb6a12d035d74ec1e444f53010ad53c6b1adf28c75aa482403c06052314a91636c2a8baa30e09af
|
||||
DIST gnucash-2.7.7.tar.bz2 13368946 BLAKE2B 06e6815af713235ea31859532911303db4fa5e8dcd50b9111aa513795963eaca29a612eeced27399441f43563753d977468dfd901a49dfa689b5d36e7b985ebf SHA512 b7d91e87c4bc4e604560f4502a86deaafa4f636e9fe2af26db53b11da9f48986c970ba0ed08cb7172ca08a5fb2da451d26976963241206c388a33555c80f28fe
|
||||
DIST gnucash-3.0.tar.bz2 13366724 BLAKE2B 4c6e87d433f203cca73f1b4ee623a4bb260bdd6812aaf24af0045384cbe8fc24cc5215b4a4bbe4f7446bfd4626ef7cf09f67f2031f49c2563784528294aae8fb SHA512 5ec13b8abe1520a7e614ceeca4c41d5dba3ebae4ec965918584963022ceb5cb3b85862289a85a72767db74a0c735214a78342a53c37e6da939ff850538174a87
|
||||
DIST gnucash-3.1-1.tar.bz2 13374530 BLAKE2B 51dcdea6b91a72288a9e9583d50edbe88303b93fe0059ea3444a0965723bb29955227df5e6eda910638f28a3eacdf367fdca1783871258b8ce396598e2b5edc0 SHA512 34d675cf1434f280345c40e6f448b3c2ac5b3cde33b15e662bbda784660ad92168e4b0d14d4fbf190cdfa6a7954806520ab4b72a7460736c78f934f803b1d5e0
|
||||
DIST gtest-1.8.0.tar.gz 1281617 BLAKE2B ac052b4d0eb0d8ded03a8c7dff05177818627b8a51f2dbc2c162b2ee2a5d1323539e7d0d02236d9ebb799995e018f0171c2fdaeb4de3bb339548265e50de79e6 SHA512 1dbece324473e53a83a60601b02c92c089f5d314761351974e097b2cf4d24af4296f9eb8653b6b03b1e363d9c5f793897acae1f0c7ac40149216035c4d395d9d
|
||||
|
||||
160
app-office/gnucash/gnucash-3.1.ebuild
Normal file
160
app-office/gnucash/gnucash-3.1.ebuild
Normal file
@@ -0,0 +1,160 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
# google{test,mock} version
|
||||
GV="1.8.0"
|
||||
PYTHON_COMPAT=( python3_{4,5,6} )
|
||||
|
||||
inherit cmake-utils gnome2-utils python-single-r1 xdg-utils
|
||||
|
||||
DESCRIPTION="A personal finance manager"
|
||||
HOMEPAGE="http://www.gnucash.org/"
|
||||
SRC_URI="https://github.com/Gnucash/${PN}/releases/download/${PV}/${P}-1.tar.bz2
|
||||
https://github.com/google/googletest/archive/release-${GV}.tar.gz -> gtest-${GV}.tar.gz"
|
||||
|
||||
SLOT="0"
|
||||
LICENSE="GPL-2"
|
||||
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
|
||||
|
||||
IUSE="aqbanking chipcard debug doc examples gnome-keyring mysql nls ofx postgres
|
||||
python quotes -register2 sqlite"
|
||||
REQUIRED_USE="
|
||||
chipcard? ( aqbanking )
|
||||
python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
# libdbi version requirement for sqlite taken from bug #455134
|
||||
#
|
||||
# dev-libs/boost must always be built with nls enabled.
|
||||
RDEPEND="
|
||||
>=dev-libs/glib-2.40.0:2
|
||||
>=dev-libs/libxml2-2.7.0:2
|
||||
>=dev-scheme/guile-2.0.0:12=[regex]
|
||||
>=sys-libs/zlib-1.1.4
|
||||
>=x11-libs/gtk+-3.14.0:3
|
||||
dev-libs/boost:=[icu,nls]
|
||||
dev-libs/icu:=
|
||||
dev-libs/libxslt
|
||||
gnome-base/dconf
|
||||
net-libs/webkit-gtk:4=
|
||||
aqbanking? (
|
||||
>=net-libs/aqbanking-5[gtk,ofx?]
|
||||
sys-libs/gwenhywfar[gtk]
|
||||
chipcard? ( sys-libs/libchipcard )
|
||||
)
|
||||
gnome-keyring? ( >=app-crypt/libsecret-0.18 )
|
||||
mysql? (
|
||||
dev-db/libdbi
|
||||
dev-db/libdbi-drivers[mysql]
|
||||
)
|
||||
ofx? ( >=dev-libs/libofx-0.9.1 )
|
||||
postgres? (
|
||||
dev-db/libdbi
|
||||
dev-db/libdbi-drivers[postgres]
|
||||
)
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
quotes? (
|
||||
>=dev-perl/Finance-Quote-1.11
|
||||
dev-perl/Date-Manip
|
||||
dev-perl/HTML-TableExtract
|
||||
)
|
||||
sqlite? (
|
||||
>=dev-db/libdbi-0.9.0
|
||||
>=dev-db/libdbi-drivers-0.9.0[sqlite]
|
||||
)
|
||||
"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
~dev-cpp/gtest-${GV}
|
||||
>=sys-devel/gettext-0.19.6
|
||||
dev-lang/perl
|
||||
dev-perl/XML-Parser
|
||||
gnome-base/gnome-common
|
||||
sys-devel/libtool
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
PDEPEND="doc? (
|
||||
~app-doc/gnucash-docs-${PV}
|
||||
gnome-extra/yelp
|
||||
)"
|
||||
|
||||
#PATCHES=( "${FILESDIR}"/${PN}-2.7.4-fix-tests-for-32bit-platforms.patch )
|
||||
|
||||
pkg_setup() {
|
||||
use python && python-single-r1_pkg_setup
|
||||
xdg_environment_reset
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local sql_on_off="OFF"
|
||||
if use mysql || use postgres || use sqlite ; then
|
||||
sql_on_off="ON"
|
||||
fi
|
||||
|
||||
local mycmakeargs=(
|
||||
-DGMOCK_ROOT="${WORKDIR}"/googletest-release-${GV}/googlemock
|
||||
-DGTEST_ROOT="${WORKDIR}"/googletest-release-${GV}/googletest
|
||||
|
||||
-DDISABLE_NLS=$(usex !nls)
|
||||
-DENABLE_REGISTER2=$(usex register2)
|
||||
-DWITH_AQBANKING=$(usex aqbanking)
|
||||
-DWITH_OFX=$(usex ofx)
|
||||
-DWITH_PYTHON=$(usex python)
|
||||
-DWITH_SQL=${sql_on_off}
|
||||
)
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
if use python ; then
|
||||
cp common/test-core/unittest_support.py \
|
||||
"${BUILD_DIR}"/common/test-core/ || die
|
||||
fi
|
||||
|
||||
cd "${BUILD_DIR}" || die
|
||||
XDG_DATA_HOME="${T}/$(whoami)" emake check
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
|
||||
rm "${ED%/}"/usr/share/doc/${PF}/README.dependencies || die
|
||||
rm "${ED%/}"/usr/share/glib-2.0/schemas/gschemas.compiled || die
|
||||
|
||||
if use examples ; then
|
||||
mv "${ED%/}"/usr/share/doc/gnucash \
|
||||
"${ED%/}"/usr/share/doc/${PF}/examples || die
|
||||
pushd "${ED%/}"/usr/share/doc/${PF}/examples/ > /dev/null || die
|
||||
rm AUTHORS DOCUMENTERS LICENSE NEWS projects.html ChangeLog* \
|
||||
*win32-bin.txt || die
|
||||
popd > /dev/null || die
|
||||
docompress -x /usr/share/doc/${PF}/examples/
|
||||
else
|
||||
rm -r "${ED%/}"/usr/share/doc/gnucash || die
|
||||
fi
|
||||
|
||||
use aqbanking && dodoc doc/README.HBCI
|
||||
use ofx && dodoc doc/README.OFX
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
gnome2_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
xdg_desktop_database_update
|
||||
xdg_mimeinfo_database_update
|
||||
|
||||
ewarn "Backup all financial files or databases before using GnuCash >=2.7.0!"
|
||||
ewarn
|
||||
ewarn "GnuCash 2.7.0 introduced large changes in its file format and database"
|
||||
ewarn "schema that WILL prevent you from reverting back to GnuCash 2.6."
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
gnome2_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
xdg_desktop_database_update
|
||||
xdg_mimeinfo_database_update
|
||||
}
|
||||
Reference in New Issue
Block a user