media-libs/leptonica: Drop old 1.86.0

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

media-libs/leptonica/Manifest

@@ -1,3 +1,2 @@
 DIST leptonica-1.85.0.tar.gz 14757419 BLAKE2B db26f30121f8fa7807068d3e55c1cc3ed2f8a7a6f8bb8cc46a240257d11842000b63a4b08542c87a90bc446ccb53a1fe36823661416ec120da8e9b199ddb8def SHA512 ad097f8238bb88f044511bedb6debfb8a1492a4636348b21ce103034d3878ae1097e7ca8de9c39ef01f34589526d7e8aee68fb1b83aae5ffc0026c04360b882c
-DIST leptonica-1.86.0.tar.gz 14802116 BLAKE2B f4bc4fd032e8587b953e04eeba98f0a48341edf6a07d7abf5da240ca9e4f4dbf371726ff9301884b94208d126a80019f64c1be15487a4f48af02811430471050 SHA512 0b50ecebb4bf46c665e02992248160019ca1771c6d700ba5bb8030dc3803595a491612665a1c07d1ebbe91ef8fa578ea54b4810ff7a1809f0a554c7018773333
 DIST leptonica-1.87.0.tar.gz 14802808 BLAKE2B ac9f698d7160a2821e57d20ea401a47458d5693d9613e1c26311cec43974c58c47d4e4322e538bc276af262736e6fc84702a0d88bea41e23ed6a459e1d74be47 SHA512 b689b1cfe4d5b884e7ede9d949149410117bbfbb85a1790c0516919f27e8746783c8a04cac9300c761d2736184fb4b2337ab6c3a2653fa9f69f82ba19b493a2d

media-libs/leptonica/leptonica-1.86.0.ebuild

@@ -1,80 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit libtool multilib-minimal
-
-DESCRIPTION="C library for image processing and analysis"
-HOMEPAGE="http://www.leptonica.org/"
-SRC_URI="https://github.com/DanBloomberg/${PN}/releases/download/${PV}/${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0/6"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
-IUSE="gif jpeg jpeg2k png static-libs test tiff utils webp zlib"
-# N.B. Tests need some features enabled:
-REQUIRED_USE="
-	tiff? ( jpeg )
-	test? ( jpeg png tiff zlib )
-"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	gif? ( >=media-libs/giflib-5.1.3:=[${MULTILIB_USEDEP}] )
-	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
-	jpeg2k? ( media-libs/openjpeg:2=[${MULTILIB_USEDEP}] )
-	png? (
-		media-libs/libpng:0=[${MULTILIB_USEDEP}]
-		virtual/zlib:=[${MULTILIB_USEDEP}]
-	)
-	tiff? ( media-libs/tiff:=[${MULTILIB_USEDEP}] )
-	webp? ( media-libs/libwebp:=[${MULTILIB_USEDEP}] )
-	zlib? ( virtual/zlib:=[${MULTILIB_USEDEP}] )"
-DEPEND="${RDEPEND}
-	test? ( media-libs/tiff[jpeg,zlib] )"
-
-DOCS=( README version-notes )
-
-src_prepare() {
-	default
-	elibtoolize
-
-	# unhtmlize docs
-	local X
-	for X in ${DOCS[@]}; do
-		awk '/<\/pre>/{s--} {if (s) print $0} /<pre>/{s++}' \
-			"${X}.html" > "${X}" || die 'awk failed'
-		rm -f -- "${X}.html"
-	done
-}
-
-multilib_src_configure() {
-	ECONF_SOURCE="${S}" econf \
-		--enable-shared \
-		$(use_with gif giflib) \
-		$(use_with jpeg) \
-		$(use_with jpeg2k libopenjpeg) \
-		$(use_with png libpng) \
-		$(use_with tiff libtiff) \
-		$(use_with webp libwebp) \
-		$(use_with webp libwebpmux) \
-		$(use_with zlib) \
-		$(use_enable static-libs static) \
-		$(multilib_native_use_enable utils programs)
-}
-
-multilib_src_test() {
-	default
-
-	# ${TMPDIR} is not respected. It used to be but it lead to issues
-	# and there have been long debates with upstream about it. :(
-	rm -rf /tmp/lept/ || die
-}
-
-multilib_src_install_all() {
-	einstalldocs
-
-	# libtool archives covered by pkg-config
-	find "${ED}" -name '*.la' -delete || die
-}