dev-python/autobahn: Bump to 21.3.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/autobahn/Manifest

@@ -4,3 +4,4 @@ DIST autobahn-20.7.1.tar.gz 1260579 BLAKE2B 925d148836348c068d179d4871267bf79c8c
 DIST autobahn-21.1.1.tar.gz 1269122 BLAKE2B 6eb8eb22d0f09a4e8d409220ee2dff60a42a4e81acee789e8f9d98649ada24174295b98936f5e0a0a211fddd6d124975aef152679fcfde7b3dca7f18dcba5b62 SHA512 8e56e8a9213e356ea4288c6ed6ba4d6e8a26f5e1f670cfc067d1e11ef4d989b4e3d33a5cac49a635e18f9d45da1d42cb1300de96afdf77898441330e3f489194
 DIST autobahn-21.2.1.tar.gz 343966 BLAKE2B 8ee40610599aad6b0e6832beb867ff7515192e9a896d4f1e1b2c731fb81c899bf530f24d28e52faa91779affb1ed93b9b79b606b1ac7d3ed26a272dfcf6a0afc SHA512 21760aeac80c1e958a338da31d405af2f37c803944032270329dde4b59e6a9f914e9a7e4ae0ae6ae5b699ddc61f0c2f6b89cb0d6d4fdc3b1b58f204d4e94a980
 DIST autobahn-21.2.2.tar.gz 350799 BLAKE2B 06c5f7517083853bcf2e4c982151caadae2c5c0c547f543f310497addda14ff6262adaf876dcd5ce25ab48fd8b9b9c816ff74f518f3aedc65627ee3390db514b SHA512 6dbad05437c92622709c140fd949706c8fbff62477cf9fa5a8bbcb8c5410661b660d548902ebec55b5a8d744cce12c9a229bceeb3d5e7e5dc4e50cb09f7e7ab7
+DIST autobahn-21.3.1.tar.gz 351296 BLAKE2B d018c8820a1accc779decdb8d392d3ff6225f80674b468145a8f29b275d6f0b1021a226dc8bc72915a792591e6d4ae8d6a33a96cf705241990ac401c8342e2c5 SHA512 dd6bf6eba6f2880860c6fa42e3925bb15d36bfb9d2354ddeb0165972848e81a308723b7f9dcd6ec3426b6286f71cb2da453590810e5d891523d92acf9fd64c52

dev-python/autobahn/autobahn-21.3.1.ebuild

@@ -0,0 +1,108 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="crypt scram test xbr"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/cbor2-5.2.0[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/flatbuffers-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
+	>=dev-python/snappy-0.5[${PYTHON_USEDEP}]
+	>=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/txaio-21.2.1[${PYTHON_USEDEP}]
+	>=dev-python/ujson-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-18.1.0[${PYTHON_USEDEP}]
+	)
+	scram? (
+		dev-python/cffi[${PYTHON_USEDEP}]
+		dev-python/argon2-cffi[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+	)
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	if use xbr ; then
+		eerror "***************"
+		eerror "Required xbr dependencies are incomplete in Gentoo."
+		eerror "So this functionality will not yet work"
+		eerror "Please file a bug if this feature is needed"
+		eerror "***************"
+	else
+		# remove xbr components
+		export AUTOBAHN_STRIP_XBR="True"
+	fi
+
+	# avoid useless rust dependency
+	sed -i -e '/cryptography/s:>=3.4.6::' setup.py || die
+
+	# remove twisted plugin cache regen in setup.py
+	# to fix tinderbox sandbox issue
+	sed -e 's/# regenerate Twisted plugin cache/# DO NOT regenerate Twisted plugin cache in Gentoo\nexit()/' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	einfo "Testing all, cryptosign using twisted"
+	local -x USE_TWISTED=true
+	cd "${BUILD_DIR}"/lib || die
+	"${EPYTHON}" -m twisted.trial autobahn || die
+	unset USE_TWISTED
+	einfo "RE-testing cryptosign and component_aio using asyncio"
+	local -x USE_ASYNCIO=true
+	pytest -vv autobahn/wamp/test/test_wamp_cryptosign.py || die
+	pytest -vv autobahn/wamp/test/test_wamp_component_aio.py || die
+	unset USE_ASYNCIO
+	rm -r .pytest_cache || die
+	rm -f "${BUILD_DIR}"/lib/twisted/plugins/dropin.cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache || die
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache || die
+}