mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
media-sound/xwax: bump to 1.8
Package-Manager: Portage-3.0.22, Repoman-3.0.3 Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST xwax-1.7.tar.gz 80745 BLAKE2B b431951651b66899b5bcceadfadc546c564123e47632aa9b395c26d706fc37cda4b5bf4f8695538e1a5e2bb0a690f125ca89705259d11df580f6a833e5d114b6 SHA512 ab0fcaf32f1fd1d6b38323095524f1932a067a3d04d40e4b043993e360411fed0c4b78bb71662581b438cb1e3005bc21659db4521a6ec704994b2e8e1b7e62d4
|
||||
DIST xwax-1.8.tar.gz 86268 BLAKE2B 7fbde34e6c1a3508da6ea8230cec7d2663503882182e403bf9bbf2b7327248c1b2e38a21392615a359d30d4a65f558e55346f99bf8f89621a18bcf9e8cf09139 SHA512 db37a16ecc5437f9b085c17e5e645e04b76a18aa7f7d8e8448a2994435596394ea7f2b52a6734194be7cf0b7099995f0f8735c2c547f3f57525339c4dc671d9d
|
||||
|
||||
@@ -0,0 +1,87 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit toolchain-funcs
|
||||
|
||||
DESCRIPTION="Digital vinyl emulation software"
|
||||
HOMEPAGE="https://xwax.org/"
|
||||
SRC_URI="https://xwax.org/releases/${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
|
||||
IUSE="alsa jack oss cdda mp3 +fallback"
|
||||
|
||||
REQUIRED_USE="
|
||||
|| ( cdda mp3 fallback )
|
||||
|| ( alsa jack oss )
|
||||
"
|
||||
|
||||
DEPEND="
|
||||
media-fonts/dejavu
|
||||
media-libs/libsdl
|
||||
media-libs/sdl-ttf
|
||||
sys-libs/glibc
|
||||
sys-libs/pam
|
||||
alsa? ( media-libs/alsa-lib )
|
||||
cdda? ( media-sound/cdparanoia )
|
||||
fallback? ( media-video/ffmpeg )
|
||||
jack? ( virtual/jack )
|
||||
mp3? ( media-sound/mpg123 )
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
${DEPEND}
|
||||
acct-group/xwax
|
||||
"
|
||||
|
||||
DOCS=( README CHANGES )
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
# Remove the forced optimization from 'CFLAGS' and 'LDFLAGS' in
|
||||
# the Makefile
|
||||
# Also remove the dependency on the .version target so we don't need
|
||||
# git just to build
|
||||
sed -i -e 's/\(^\(LD\|C\)FLAGS.*\)-O[0-9]\(.*\)/\1\3/g' \
|
||||
-e 's/^xwax\.o:.*\.version//' \
|
||||
Makefile || die "sed failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
tc-export CC
|
||||
econf \
|
||||
--prefix "${EPREFIX}/usr" \
|
||||
$(use_enable alsa) \
|
||||
$(use_enable jack) \
|
||||
$(use_enable oss)
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
# EXECDIR is the default directory in which xwax will look for
|
||||
# the 'xwax-import' and 'xwax-scan' scripts
|
||||
emake EXECDIR="\$(BINDIR)" VERSION="${PV}" xwax
|
||||
}
|
||||
|
||||
src_install() {
|
||||
# This is easier than setting all the environment variables
|
||||
# needed, running the sed script required to get the man directory
|
||||
# correct, and removing the GPL-2 after a 'make install' run
|
||||
dobin xwax
|
||||
newbin scan xwax-scan
|
||||
newbin import xwax-import
|
||||
doman xwax.1
|
||||
|
||||
dodoc ${DOCS}
|
||||
|
||||
insinto "/etc/security/limits.d"
|
||||
newins "${FILESDIR}/xwax-etc-security-limits.conf" xwax.conf
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
elog "Be sure to add any users that will be using ${PN} to the"
|
||||
elog "\"${PN}\" group. Doing so will allow processes that user"
|
||||
elog "runs to request realtime priority."
|
||||
}
|
||||
Reference in New Issue
Block a user