xfce-base/xfwm4: Bump to 4.14.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfwm4/Manifest

@@ -1 +1,2 @@
 DIST xfwm4-4.14.0.tar.bz2 1122735 BLAKE2B 1865c0714ddd4107e806de5607ef0e260c3fd1b6c9abcbec112a126bf780f456873786595a4cb924ce2154a40868670699519e4bb4576d971f853f7d3f63e98c SHA512 27261b08b53ba7e70db547db81775154c2f4285ab0f1f8336bd9ef0aeacb3ab705ae8ac5b05f9ac23de550a9065e76487dc93a99e553549bff1c25ceb5216939
+DIST xfwm4-4.14.1.tar.bz2 1165131 BLAKE2B 77c8e13793a0fc97d006e038c19db13f0a3c646979824e6141c5bdfc34b0e630dece04cd70d7876ab735f99a0ebebbc22a2ef6d370fe3036c0d3aec1247be42f SHA512 2e924498fa467837fae6a148958c0bbb27fc310383c06a4d101928762781f3dbc48e51ff67ddc5c7ce7d04f6af2ff63c64d1d6a0d5eebed224eb23db9ebeea73

xfce-base/xfwm4/xfwm4-4.14.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="Window manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="opengl startup-notification +xcomposite +xpresent"
+
+RDEPEND=">=dev-libs/glib-2.20
+	>=x11-libs/gtk+-3.20:3
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/pango
+	>=x11-libs/libwnck-3.14:3
+	>=xfce-base/libxfce4util-4.10:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/xfconf-4.13:=
+	opengl? ( media-libs/libepoxy:=[X(+)] )
+	startup-notification? ( x11-libs/startup-notification )
+	xpresent? ( x11-libs/libXpresent )
+	xcomposite? (
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXfixes
+		)"
+# libICE/libSM: not really used anywhere but checked by configure
+#   https://bugzilla.xfce.org/show_bug.cgi?id=11914
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	x11-libs/libICE
+	x11-libs/libSM
+	xfce-base/exo
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog COMPOSITOR NEWS README TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable opengl epoxy)
+		$(use_enable startup-notification)
+		--enable-xsync
+		--enable-render
+		--enable-randr
+		$(use_enable xpresent)
+		$(use_enable xcomposite compositor)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}