dev-python/absl-py: Bump to 2.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/absl-py/Manifest

@@ -1 +1,2 @@
 DIST abseil-py-2.1.0.gh.tar.gz 235261 BLAKE2B 85232156e722cb874e29e1f92513b24836553476d5ff379e8df32d307ca21709b5869edd80a3bb7fe757ae585bb45df21c89ae6f2218147a5812f171d946e094 SHA512 298a876ed850085836cb1ff6fddf98aca6a3283780bece8c0a7d118fd4e16cc258e51f721e4a5fcbe62b23d2da05638475d426bb650b0694ff7c1d0119e3be97
+DIST abseil-py-2.2.0.gh.tar.gz 238608 BLAKE2B f8bc8e436064c687791d68d37137d10d18b2cfda055f8c814959e52883c10cf461c7220315a5f42b1e53a2a6c893e92498a57d92a3236abee7c18ea085f98c2f SHA512 91ead7f112ae8397f78a088c1784312e9784f5a46f52304607802a1bd485becc5144d6e437b9e2cf4112ac2194d7c0f91b811f329a38c2811971161b4bffbd30

dev-python/absl-py/absl-py-2.2.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+MY_P=abseil-py-${PV}
+DESCRIPTION="Abseil Python Common Libraries"
+HOMEPAGE="
+	https://github.com/abseil/abseil-py/
+	https://pypi.org/project/absl-py/
+"
+SRC_URI="
+	https://github.com/abseil/abseil-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# what a nightmare... well, we could have called bazel but that would
+	# even worse
+	local helpers=(
+		absl/flags/tests/argparse_flags_test_helper.py:absl/flags/tests/argparse_flags_test_helper
+		absl/logging/tests/logging_functional_test_helper.py:absl/logging/tests/logging_functional_test_helper
+		absl/testing/tests/absltest_fail_fast_test_helper.py:absl/testing/tests/absltest_fail_fast_test_helper
+		absl/testing/tests/absltest_filtering_test_helper.py:absl/testing/tests/absltest_filtering_test_helper
+		absl/testing/tests/absltest_randomization_testcase.py:absl/testing/tests/absltest_randomization_testcase
+		absl/testing/tests/absltest_sharding_test_helper.py:absl/testing/tests/absltest_sharding_test_helper
+		absl/testing/tests/absltest_sharding_test_helper_no_tests.py:absl/testing/tests/absltest_sharding_test_helper_no_tests
+		absl/testing/tests/absltest_test_helper.py:absl/testing/tests/absltest_test_helper
+		absl/testing/tests/absltest_test_helper_skipped.py:absl/testing/tests/absltest_test_helper_skipped
+		absl/testing/tests/xml_reporter_helper_test.py:absl/testing/tests/xml_reporter_helper_test
+		absl/tests/app_test_helper.py:absl/tests/app_test_helper_pure_python
+	)
+
+	local x
+	for x in "${helpers[@]}"; do
+		local script=${x%:*}
+		local sym=${x#*:}
+		sed -i -e "1i#!/usr/bin/env python" "${script}" || die
+		chmod +x "${script}" || die
+		ln -s "${script##*/}" "${sym}" || die
+	done
+
+	# i don't wanna know how these pass for upstream with wrong helper names
+	sed -e 's:\(app_test_helper\)\.py:\1_pure_python:' \
+		-i absl/tests/app_test.py || die
+	sed -e 's:\(logging_functional_test_helper\)\.py:\1:' \
+		-i absl/logging/tests/logging_functional_test.py || die
+}
+
+python_test() {
+	local -x PYTHONPATH=.
+	local fails=0
+	while read -r -d '' x; do
+		ebegin "${x}"
+		"${EPYTHON}" "${x}"
+		eend ${?} || : "$(( fails += 1 ))"
+	done < <(find -name '*_test.py' -print0)
+
+	[[ ${fails} -ne 0 ]] && die "${fails} tests failed on ${EPYTHON}"
+
+	# we actually need to clean this up manually before running the test
+	# suite again...
+	chmod -R u+rwX "${T}"/absl_testing || die
+	rm -rf "${T}"/absl_testing || die
+}