kde-misc/tellico: add 4.1

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-misc/tellico/Manifest

@@ -1 +1,2 @@
 DIST tellico-4.0.1.tar.xz 6779796 BLAKE2B 0f3fb590a5fc96956de2ce9527f1c866a864b371a8e1cd348bc574004ac08a9f43f73e11c85e45f58bbb778d2f9c7b68f3ddcafcc6bac515468ddd1253e063cd SHA512 d4b54a9c1a65928cf19bd8134723d454950d154bb9eeee47e5cb21fa1e9497192714d4222a02b63627d7d49248f3da794c76ce7dae22cec2496d44ad8cf850ee
+DIST tellico-4.1.tar.xz 6843316 BLAKE2B fbf386d48f7927d920ae858b96ab5d5b114ff1f6c89d094ca4a467cc5e12ce85a97369c17d0e142b6665cd0bb01d50a914763419636872e13004ba7791866142 SHA512 fa72ddcfa9aaf5776bed47edcea4520d40275375abeafce5c936d5e5c18b1495efa7d041abc96cc3d02655c71403fd0889585aeb6c20bed3c9b28297ad467d66

kde-misc/tellico/tellico-4.1.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit ecm kde.org
+
+DESCRIPTION="Collection manager based on KDE Frameworks"
+HOMEPAGE="https://tellico-project.org/"
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	SRC_URI="https://tellico-project.org/files/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+IUSE="bibtex cddb discid pdf scanner semantic-desktop taglib v4l xmp yaz"
+
+# tests need network access
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=dev-qt/qtcharts-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	>=kde-frameworks/sonnet-${KFMIN}:6
+	bibtex? ( >=dev-perl/Text-BibTeX-0.780.0-r1 )
+	cddb? ( kde-apps/libkcddb:6 )
+	discid? ( dev-libs/libcdio:= )
+	pdf? ( app-text/poppler[qt6] )
+	scanner? ( kde-apps/libksane:6 )
+	semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:6 )
+	taglib? ( >=media-libs/taglib-1.5:= )
+	v4l? ( >=media-libs/libv4l-0.8.3 )
+	xmp? ( >=media-libs/exempi-2:= )
+	yaz? ( >=dev-libs/yaz-2:0= )
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Csv=ON
+		-DENABLE_BTPARSE=$(usex bibtex)
+		$(cmake_use_find_package cddb KCddb6)
+		$(cmake_use_find_package discid CDIO)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package scanner KSaneWidgets6)
+		$(cmake_use_find_package semantic-desktop KF6FileMetaData)
+		$(cmake_use_find_package taglib Taglib)
+		-DENABLE_WEBCAM=$(usex v4l)
+		$(cmake_use_find_package xmp Exempi)
+		$(cmake_use_find_package yaz Yaz)
+	)
+
+	ecm_src_configure
+}