sci-visualization/labplot: 2.7.0 version bump

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-visualization/labplot/Manifest

@@ -1 +1,2 @@
 DIST labplot-2.6.0.tar.xz 12360732 BLAKE2B f6259de30deb0adb4ddd47f0401fe8753a277aa01ade27c220ec832eb7f6c3e568c765085d2567529799777c9fe2442da777bd4089e5f488cc1aefb25a61d5a8 SHA512 6ebc96b3cfb25ebd62a6631d8cca0d9574f84548c04271eb8a10ff3ef9ebbdd0bf842b9b6129a995953412c5e6f902440dc91dbaa01d97fc220d7f6b19dc46af
+DIST labplot-2.7.0.tar.xz 13306532 BLAKE2B 044f6f1e552b6ccbd56791e39af240c97f0c572fae66ede0bbc13e172a88b652b0c42182fa4f6742b386dfd9c17f3041180841fe531387a9f44bd9b00adb8c09 SHA512 73e10ed98694b7633e80ffa7745733392cf9ce36f45e4ef6432d661b015dd3e821ddc791223a32fa55115c68f0d82b90464080915f8bb55cd1907610151a2d0a

sci-visualization/labplot/labplot-2.7.0.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Scientific data analysis and visualisation based on KDE Frameworks"
+HOMEPAGE="https://labplot.kde.org/ https://kde.org/applications/education/org.kde.labplot2"
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="5"
+IUSE="cantor fftw fits hdf5 libcerf netcdf root"
+
+# not packaged: dev-qt/qtmqtt, bug 683994
+BDEPEND="
+	sys-devel/bison
+	sys-devel/gettext
+"
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtserialport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	>=sci-libs/gsl-1.15:=
+	cantor? (
+		>=kde-apps/cantor-19.08.0:5
+		>=kde-frameworks/kparts-${KFMIN}:5
+		>=kde-frameworks/kservice-${KFMIN}:5
+	)
+	fftw? ( sci-libs/fftw:3.0= )
+	fits? ( sci-libs/cfitsio:= )
+	hdf5? ( sci-libs/hdf5:= )
+	libcerf? ( sci-libs/libcerf )
+	netcdf? ( sci-libs/netcdf:= )
+	root? (
+		app-arch/lz4
+		sys-libs/zlib
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CANTOR=$(usex cantor)
+		-DENABLE_FFTW=$(usex fftw)
+		-DENABLE_FITS=$(usex fits)
+		-DENABLE_HDF5=$(usex hdf5)
+		-DENABLE_LIBCERF=$(usex libcerf)
+		-DENABLE_NETCDF=$(usex netcdf)
+		-DENABLE_ROOT=$(usex root)
+		-DENABLE_TESTS=$(usex test)
+		-DENABLE_MQTT=OFF
+	)
+
+	ecm_src_configure
+}

sci-visualization/labplot/labplot-9999.ebuild

@@ -50,9 +50,9 @@ DEPEND="
 	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
 	>=sci-libs/gsl-1.15:=
 	cantor? (
+		>=kde-apps/cantor-19.08.0:5
 		>=kde-frameworks/kparts-${KFMIN}:5
 		>=kde-frameworks/kservice-${KFMIN}:5
-		>=kde-apps/cantor-19.08.0:5
 	)
 	fftw? ( sci-libs/fftw:3.0= )
 	fits? ( sci-libs/cfitsio:= )