gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 17:09:10 -07:00
Code Issues Projects Releases Wiki Activity

media-libs/babl: add 0.1.118

Browse Source 
Drop old babl compatibility symlink. With the context in the bug it
appears to have been re-added the wrong way around after upstream
explicitly moved to versioned pkgconfig files.

See-Also: d9bedbf987
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/45004
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Alfred Wingate
2025-12-11 14:59:09 +02:00
committed by Sam James
parent 8380332027
commit 976b9270ab
3 changed files with 63 additions and 1 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
media-libs/babl/Manifest
View File

@@ -1,2 +1,3 @@
DIST babl-0.1.112.tar.xz 318924 BLAKE2B 3eeacf6acd970a51a0ae47b548bc18ded33ecc9da7f7b34e041f70b45725b932a35a9a17cd114cdf0416928eb77e09ff4aeb20a20c5fd487b645dfe10a481a2f SHA512 18aef6baffbe978a6cdb05cf62fb8f14a81ba48ccb7dfc29a5581c9d46d8e34e2a8601bcea40ac5700661fe16bbc1bf72684f9f17e5c825c8fd7fec27c2c872b
DIST babl-0.1.116.tar.xz 321804 BLAKE2B a879af9b1e3eb8fa12a86be89744c7ab200f283380c729602ada9731e2cb3f1788232c4a486dfd088424f026996d528a4b47004b331d36575906deca40f9243a SHA512 44bdbf64905280e661b48123c107bd3c3e09c5e13dc641138e7aeea772f555191d145f7af07a5dc64339b90284e1b379209592961454f0dd23487bf87abe33d0
DIST babl-0.1.118.tar.xz 325412 BLAKE2B 830eac26dc03cdbe895217fa98fda83ef93ef4f778b32914171f2dd0459652e611139f50230d719f22ebd11833f033b42cd58e8822c00134bb39fe7dd217931e SHA512 6a361135045566b5a35b7c2df8e9f0a0b1c6e910aa73aafecb621446d333bcbfc50e925ceac675b83b548a872d53eba2c03bcbccb504b47089c737b0ffb53d9d

61
media-libs/babl/babl-0.1.118.ebuild Normal file
View File

@@ -0,0 +1,61 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
VALA_USE_DEPEND=vapigen
inherit meson gnome2-utils vala
if [[ ${PV} == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
else
SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv -sparc ~x86 ~x64-macos ~x64-solaris"
fi
DESCRIPTION="A dynamic, any to any, pixel format conversion library"
HOMEPAGE="https://gegl.org/babl/"
LICENSE="LGPL-3"
SLOT="0"
IUSE="introspection lcms vala cpu_flags_x86_avx2 cpu_flags_x86_f16c cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
REQUIRED_USE="vala? ( introspection )"
BDEPEND="
virtual/pkgconfig
vala? ( $(vala_depend) )
"
RDEPEND="
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
lcms? ( >=media-libs/lcms-2.13.1:2 )
"
DEPEND="${RDEPEND}"
src_prepare() {
default
gnome2_environment_reset
}
src_configure() {
use vala && vala_setup
# Automagic rsvg support is just for website generation we do not call,
# so we don't need to fix it
# w3m is used for dist target thus no issue for us that it is automagically
# detected
local emesonargs=(
-Dwith-docs=false
$(meson_use introspection enable-gir)
$(meson_feature lcms with-lcms)
$(meson_use vala enable-vapi)
$(meson_use cpu_flags_x86_avx2 enable-avx2)
$(meson_use cpu_flags_x86_f16c enable-f16c)
$(meson_use cpu_flags_x86_mmx enable-mmx)
$(meson_use cpu_flags_x86_sse enable-sse)
$(meson_use cpu_flags_x86_sse2 enable-sse2)
$(meson_use cpu_flags_x86_sse4_1 enable-sse4_1)
)
meson_src_configure
}

2
media-libs/babl/babl-9999.ebuild
View File

@@ -12,7 +12,7 @@ if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
else
SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv -sparc ~x86 ~x64-macos ~x64-solaris"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv -sparc ~x86 ~x64-macos ~x64-solaris"
fi
DESCRIPTION="A dynamic, any to any, pixel format conversion library"