xfce-base/xfce4-panel: Bump to 4.21.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.20.7.tar.bz2 2311827 BLAKE2B b9256049a24c0344e71dd5b53925c75370b978fb110b8a06c9f2465160592983a05bb655a199e5cc236a35587c80f74c0f75053b55455ee5ffdcf8908bd1e7ea SHA512 776319ce0dc0c087f8c1f963b34e5876870d21a91a47cca9b8bcc651dc469a59a0cabc47abdb170e5ab5420783e1d65354ced2778716159751da325697e6107f
 DIST xfce4-panel-4.21.1.tar.xz 827800 BLAKE2B 32e36deb87b64ff2f2eb415a237db5bc8f7a64ea8069218920adcb1f7d62ac9e8269e8a603a231bd327587398f3ad9ccfd4dfeb9a2ee63cc63f52ef595012b79 SHA512 ce662bf001d8984f3162e906429d4a804b2d739ccaa7a1f6187698ff8cea8cea1d7f2e7a8d4038d347fcb0951cac5fa7ddf5486d779b7eacf37e1941ae6c160c
+DIST xfce4-panel-4.21.2.tar.xz 844084 BLAKE2B 15504ffa5ca2406144be3487c39920d2a743f8414a8957e3b7c3594ec64c2b10d09614d6b7d895ae8cda6bce544f8b40639cdc7f8fe53e81ca721478a59476c3 SHA512 2cd5f1fc83bbbd2291ec6ac63e8c080103d4e42d13e0561a620778314a2f18598e1d0519e952fb57a84164b2ef4c1140b4d3f4bb540ab430800d2e46d347a4c3

xfce-base/xfce4-panel/xfce4-panel-4.21.2.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-panel/start
+	https://gitlab.xfce.org/xfce/xfce4-panel/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+dbusmenu gtk-doc introspection vala wayland X"
+REQUIRED_USE="
+	|| ( wayland X )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.74.0
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
+	>=xfce-base/exo-4.18.0:=
+	>=xfce-base/garcon-4.18.0:=
+	>=xfce-base/libxfce4ui-4.21.3:=
+	>=xfce-base/libxfce4util-4.18.0:=[introspection?,vala?]
+	>=xfce-base/libxfce4windowing-4.20.1:=[X?]
+	>=xfce-base/xfconf-4.18.0:=
+	dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	wayland? (
+		>=dev-libs/wayland-1.20
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXext-1.0.0
+		x11-libs/libwnck:3
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	gtk-doc? ( dev-util/gtk-doc )
+	vala? ( $(vala_depend) )
+	dev-build/xfce4-dev-tools
+	>=dev-util/gdbus-codegen-2.80.5-r1
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc)
+		$(meson_use introspection)
+		$(meson_feature vala)
+		$(meson_feature X x11)
+		$(meson_feature wayland)
+		$(meson_feature wayland gtk-layer-shell)
+		$(meson_feature dbusmenu)
+	)
+
+	use vala && vala_setup
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}