net-libs/librist: new package, add 0.2.8

Initially no ristreceiver/ristsender tools support, as that needs fixing of
automagic prometheus deps first.

Signed-off-by: Mart Raudsepp <leio@gentoo.org>

net-libs/librist/Manifest

@@ -0,0 +1 @@
+DIST librist-v0.2.8.tar.bz2 2580630 BLAKE2B 665b8111dceb12d86a51739c1e3205f4cf1059fbb14909db3988ad0529c9a11bd25b73b82d4f3e4e85fef1036d3d25d390b3eeac82ed15bab4145e52c46e8ee8 SHA512 05fe5eec411a53c9cf3f55a60b8aed1881f9ebe2960b3ac5f157a1c5c9f42865da58bb90a2f891450f1ae9178b949cdad282dfa3f216599a50b87da92b8a7449

net-libs/librist/librist-0.2.8.ebuild

@@ -0,0 +1,48 @@
+# Copyright 2018-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Library for Reliable Internet Stream Transport (RIST) protocol"
+HOMEPAGE="https://code.videolan.org/rist/librist"
+
+SRC_URI="https://code.videolan.org/rist/librist/-/archive/v${PV}/librist-v${PV}.tar.bz2"
+KEYWORDS="~arm64"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/cJSON
+	net-libs/mbedtls:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/librist-v${PV}"
+
+src_configure() {
+	local emesonargs=(
+		-Dstatic_analyze=false
+		$(meson_use test)
+		-Dbuiltin_cjson=false
+		-Dbuiltin_mbedtls=false
+		# Tools have automagic libmicrohttpd dep for prometheus;
+		# needs solved before exposing; look into use_tun once enabled
+		-Dbuilt_tools=false
+		-Dfallback_builtin=false
+		-Duse_mbedtls=true
+		-Duse_nettle=false
+		-Duse_tun=false # Used only by tools
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# multicast tests fails with FEATURES=network-sandbox
+	meson_src_test --no-suite multicast
+}

net-libs/librist/metadata.xml

@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>leio@gentoo.org</email>
+		<name>Mart Raudsepp</name>
+	</maintainer>
+</pkgmetadata>