games-strategy/naev: drop 0.12.3

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

games-strategy/naev/Manifest

@@ -1,2 +1 @@
-DIST naev-0.12.3-source.tar.xz 465309428 BLAKE2B c213dde47352d809d10c226978165bf0b4c5257afcc77866c4b7ca2a6f06bc5580fb685ca2428cb0ba09474b03d13b27cfbd2f6751da14c3503b3f481b57a6c3 SHA512 6ae2701d66a198f128e8f2d87a5f6177ef8dcba64ef5ac1110e0af94bd74a46b3183f1a6771d632e9da79e29fc8ee502cfaa36ab7a8e259e681efe9946a9d239
 DIST naev-0.12.4-source.tar.xz 466125960 BLAKE2B 3b39a7c6e969762580b380e378ea3e078792be14848b0d30d564fa9bf4586f1219ff0b72f419cf02aa364c2bc56aeb47cc39ef07f77b0e3108894e7235ff9504 SHA512 4eaf44a983e218e1c3b8d730d768cfd659fa90efb140b8cbf18d743276eba2e3af71dc66ab47dd369e9eedabcafc109b79de4f97c93c8d38306c74d59a0340ae

games-strategy/naev/naev-0.12.3.ebuild

@@ -1,102 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{10..13} )
-inherit lua-single meson python-any-r1 xdg
-
-DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
-HOMEPAGE="https://naev.org/"
-SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
-
-LICENSE="
-	GPL-3+
-	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
-	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain
-"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc"
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-# tests are very basic, equivalent to just starting the game and checking if
-# can see the main menu -- but this breaks easily with software rendering and
-# some Xorg/mesa versions, simpler to do manually than try to keep this working
-RESTRICT="test"
-
-# dlopen: libglvnd
-RDEPEND="
-	${LUA_DEPS}
-	app-text/cmark:=
-	dev-games/physfs
-	dev-libs/libpcre2:=
-	dev-libs/libunibreak:=
-	dev-libs/libxml2
-	dev-libs/libyaml
-	dev-libs/nativefiledialog-extended
-	media-libs/freetype:2
-	media-libs/libglvnd
-	media-libs/libsdl2[joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	media-libs/sdl2-image[png,webp]
-	net-libs/enet:1.3=
-	sci-libs/cholmod
-	sci-libs/cxsparse
-	sci-libs/openblas
-	sci-libs/suitesparse
-	sci-mathematics/glpk:=
-	virtual/libintl
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
-	sys-devel/gettext
-	doc? (
-		app-text/doxygen
-		dev-lua/ldoc
-		media-gfx/graphviz
-	)
-"
-
-python_check_deps() {
-	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	lua-single_pkg_setup
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369)
-	sed -i "/subdir('glcheck')/d" test/meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		# *can* do lua5-1 but upstream uses+test luajit most (bug #946881)
-		-Dluajit=enabled
-		$(meson_feature doc docs_c)
-		$(meson_feature doc docs_lua)
-	)
-
-	meson_src_configure
-}
-
-src_install() {
-	local DOCS=( CHANGELOG Readme.md )
-	meson_src_install
-
-	if use doc; then
-		dodir /usr/share/doc/${PF}/html
-		mv -- "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
-		rm -r -- "${ED}"/usr/doc || die
-	fi
-
-	rm -r -- "${ED}"/usr/share/doc/naev || die
-}