dev-python/absl-py: Bump to 1.3.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/absl-py/Manifest

@@ -1 +1,2 @@
 DIST abseil-py-1.2.0.gh.tar.gz 219456 BLAKE2B ec7d878692dcf0cbe879cd7df51bc1b8ceeae945b053419b4a024a637e726064128af69fe077a26413f8562dd4a35830b340d000a6c9d520c7674b81a7e417ae SHA512 f363814ed65a68ae4bfd833dc095491349349e70327c0a87ad68ddc3b8429dacc78aaa16d2ff0d733487a12a2ab09094d4ccd1c1133981f65c12d3715cee410d
+DIST abseil-py-1.3.0.gh.tar.gz 224655 BLAKE2B 7f5c329c159a3b8d3fd7fc37ab36649d7711120ab41a2c052deb383aeae115b8ffe22e0f9c933e6cfe83e19013a2733d037954411f0f6d4acde1a7ecb3131973 SHA512 5631368b1f86dbc73d5261dc07a2693c8effb2534745fe4f19db26f908c7afff9f440a1545f16d1356092ac9a9fda2fdde97fc8977100e162765d9c224d7a66d

dev-python/absl-py/absl-py-1.3.0.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=abseil-py-${PV}
+DESCRIPTION="Abseil Python Common Libraries"
+HOMEPAGE="
+	https://github.com/abseil/abseil-py/
+	https://pypi.org/project/absl-py/
+"
+SRC_URI="
+	https://github.com/abseil/abseil-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	# what a nightmare... well, we could have called bazel but that would
+	# even worse
+	local helpers=(
+		absl/flags/tests/argparse_flags_test_helper.py:absl/flags/tests/argparse_flags_test_helper
+		absl/logging/tests/logging_functional_test_helper.py:absl/logging/tests/logging_functional_test_helper
+		absl/testing/tests/absltest_fail_fast_test_helper.py:absl/testing/tests/absltest_fail_fast_test_helper
+		absl/testing/tests/absltest_filtering_test_helper.py:absl/testing/tests/absltest_filtering_test_helper
+		absl/testing/tests/absltest_randomization_testcase.py:absl/testing/tests/absltest_randomization_testcase
+		absl/testing/tests/absltest_sharding_test_helper.py:absl/testing/tests/absltest_sharding_test_helper
+		absl/testing/tests/absltest_test_helper.py:absl/testing/tests/absltest_test_helper
+		absl/testing/tests/xml_reporter_helper_test.py:absl/testing/tests/xml_reporter_helper_test
+		absl/tests/app_test_helper.py:absl/tests/app_test_helper_pure_python
+	)
+
+	local x
+	for x in "${helpers[@]}"; do
+		local script=${x%:*}
+		local sym=${x#*:}
+		sed -i -e "1i#!/usr/bin/env python" "${script}" || die
+		chmod +x "${script}" || die
+		ln -s "${script##*/}" "${sym}" || die
+	done
+
+	# i don't wanna know how these pass for upstream with wrong helper names
+	sed -i -e 's:\(app_test_helper\)\.py:\1_pure_python:' \
+		absl/tests/app_test.py || die
+	sed -i -e 's:\(logging_functional_test_helper\)\.py:\1:' \
+		absl/logging/tests/logging_functional_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTHONPATH=.
+	local fails=0
+	while read -r -d '' x; do
+		ebegin "${x}"
+		"${EPYTHON}" "${x}"
+		eend ${?} || : "$(( fails += 1 ))"
+	done < <(find -name '*_test.py' -print0)
+
+	[[ ${fails} -ne 0 ]] && die "${fails} tests failed on ${EPYTHON}"
+
+	# we actually need to clean this up manually before running the test
+	# suite again...
+	chmod -R u+rwX "${T}"/absl_testing || die
+	rm -rf "${T}"/absl_testing || die
+}