media-libs/libmediainfo: drop 23.10

Signed-off-by: Sam James <sam@gentoo.org>

media-libs/libmediainfo/Manifest

@@ -1,2 +1 @@
-DIST libmediainfo_23.10.tar.xz 1977204 BLAKE2B e64481694c651b16bf72e18d5e68069f63efc481b465b6eb7d1d6a8c3e7de84aaabbc212fce8d734f7dd6d082a6ffcf1cdf040f410fd16554bf20db5460c3db4 SHA512 fc7f6b4ff811e9656bfd795325511d53def3e78016a005cfd3439af955a3a6c13ef06dd72dd0685441e2419ed7d141bf762394f8b3d8a9bd00ad2780dc4acbb6
 DIST libmediainfo_24.11.tar.xz 2096092 BLAKE2B 4080c34afa7e0a3ff2c9424e95ae4c461d2535f715bcc9812f30953be9b127d73100ba13835a5e77baa383bef0e089333a7ebcf891ce4e461d91d3388b1972e2 SHA512 3a7c889b09be4b17696288ac5a773684fed2dc608f9c1da346e790524b8bea372cedf5573e602dc48e10f61a17d314c8bd48764e5365dabe2c0222687e904a26

media-libs/libmediainfo/libmediainfo-23.10.ebuild

@@ -1,92 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# These must be bumped together:
-# - media-libs/libzen (if a release is available)
-# - media-libs/libmediainfo
-# - media-video/mediainfo
-
-MY_PN="MediaInfo"
-inherit autotools edos2unix flag-o-matic
-
-DESCRIPTION="MediaInfo libraries"
-HOMEPAGE="https://mediaarea.net/en/MediaInfo https://github.com/MediaArea/MediaInfoLib"
-SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
-S="${WORKDIR}"/${MY_PN}Lib/Project/GNU/Library
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~loong ~ppc ~ppc64 ~riscv x86"
-IUSE="curl doc mms"
-
-# Tests try to fetch data from online sources
-RESTRICT="test"
-
-# The libzen dep usually needs to be bumped for each release!
-RDEPEND="
-	dev-libs/tinyxml2:=
-	>=media-libs/libzen-0.4.41
-	virtual/zlib:=
-	curl? ( net-misc/curl )
-	mms? ( >=media-libs/libmms-0.6.1 )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	doc? ( app-text/doxygen )
-"
-
-src_prepare() {
-	default
-
-	sed -i 's:-O2::' configure.ac || die
-
-	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
-
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		--enable-shared \
-		--disable-static \
-		--disable-staticlibs \
-		--with-libtinyxml2 \
-		$(use_with curl libcurl) \
-		$(use_with mms libmms)
-}
-
-src_compile() {
-	default
-
-	if use doc; then
-		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc || die
-		doxygen Doxyfile || die
-	fi
-}
-
-src_install() {
-	if use doc; then
-		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
-	fi
-
-	default
-
-	edos2unix ${PN}.pc #414545
-	insinto /usr/$(get_libdir)/pkgconfig
-	doins ${PN}.pc
-
-	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
-		insinto /usr/include/${MY_PN}/${x}
-		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
-	done
-
-	insinto /usr/include/${MY_PN}DLL
-	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
-
-	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
-
-	find "${ED}" -name '*.la' -delete || die
-}