dev-python/translate-toolkit: Bump to 3.13.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1 +1,2 @@
 DIST translate-3.12.2.gh.tar.gz 1202828 BLAKE2B fdfc6ea91d0e0fe9f36e1352247463fe04ff3f4cdd13dd969077ccf0dde984250303872f6bb605dcd1628a1089d81dd98b36dfd68e92c3030c740d65899a70ba SHA512 7488f45521f1744d8d457ce5f74a4955a0e4468af8b3f5be06410667f2c1e52a3dacd3b959330e6c2eb5b3a443c1e2c761538896352576f5090ce27dbfc8edab
+DIST translate-3.13.0.gh.tar.gz 1171837 BLAKE2B 9c6212d26749eac652369e94d2b653f67b364afc9f9125c5125d19e3cabc1bb36bd27bc172ad93d28cb6cdf57ed2b245336664b6b4954db9bbbfb4a8ad92b3f9 SHA512 7c6f87ec32c81a14d1775dc24d43e49b79fdf8473a4380c93a2af1532bed32a9733ee755641ce26852b1bd63acffa2110598c5fc3010bbf9de40e8a0f32af308

dev-python/translate-toolkit/translate-toolkit-3.13.0.ebuild

@@ -0,0 +1,118 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/Levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+# Technically, the test suite also has undeclared dependency
+# on dev-python/snapshottest but all the tests using it are broken
+# anyway, so we skip them.
+BDEPEND="
+	test? (
+		dev-python/phply[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
+	# correctly, so we need to reassemble all data files in a single directory
+	local -x XDG_DATA_HOME=${T}/share
+	cp -r translate/share "${T}/" || die
+	cp -r "${ESYSROOT}/usr/share"/gaupol "${XDG_DATA_HOME}"/ || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+		# all tests based on snapshottest are broken and I'm too tired
+		# to figure this out
+		tests/translate/tools/test_pocount.py::test_{cases,output}
+		tests/translate/tools/test_junitmsgfmt.py::test_output
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		tests/translate/storage/test_fluent.py
+		# changes directory and does not change it back, sigh
+		tests/odf_xliff/test_odf_xliff.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr
+	doins -r translate/share
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+}