x11-libs/fltk: drop 1.4.1

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

x11-libs/fltk/Manifest

@@ -1,3 +1,2 @@
 DIST fltk-1.3.8-source.tar.gz 5335306 BLAKE2B 8c2d2fca4243c0e7c5a8aa46083940f99c8b3e7873d39d6e590a4b66587876393f209e5e7e5eaf4a4cc13f0f97cb03671d97129853b0146eeab409aaf687935e SHA512 5c1cbfc156c49888e25b90dcb9b1ab86a03447e08e00864c3c7ae8a0e32cfbd9154ee630054235c9edfd29fd1d0371ae77eff7b78094fb660dbbdec5cecfc8fb
-DIST fltk-1.4.1-source.tar.bz2 8456879 BLAKE2B 0301cfa7f47cde892b390ccabc1724d055cee2544cec6afe60cb1d62fed644d0100865e1889b70c06b8c4169a1af4285500a746e4c82ecb4908567c5887fc084 SHA512 90b223f66e3a8eb23225a259cddfeb90f1f8744ff6a366f274923c1c34d251e028835755d1738efb53398ac7e45e362a71542978faef04fc3d84a87f7b722037
 DIST fltk-1.4.2-source.tar.bz2 8462860 BLAKE2B 4bc4e0cddf41b7173047ce07cee7f9428192058cf25217aa9651fccb422ad2625ac2b9913d9d0cfff12aeefcf289a83c989dbbc4e664331b3c2721e3bba5e5f4 SHA512 65f4546c3b80c48a39cd719a7bdfd8bbb46c670b1606af22ebfaf67a60f1f2b5b01b111c0eea7729506038613c75dcec15efb93607973d3845181e0e8444f81e

x11-libs/fltk/fltk-1.4.1.ebuild

@@ -1,113 +0,0 @@
-# Copyright 2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake edo xdg
-
-DESCRIPTION="Fast Light GUI Toolkit"
-HOMEPAGE="https://www.fltk.org/"
-SRC_URI="https://github.com/fltk/fltk/releases/download/release-${PV}/${P}-source.tar.bz2"
-
-LICENSE="FLTK LGPL-2 MIT ZLIB"
-SLOT="1/$(ver_cut 1-2)" # README.abi-version.txt
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
-IUSE="+X +cairo doc examples opengl static-libs test wayland"
-REQUIRED_USE="
-	|| ( X wayland )
-	wayland? ( cairo )
-"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	media-libs/libjpeg-turbo:=
-	media-libs/libpng:=
-	sys-libs/zlib:=
-	X? (
-		x11-libs/libX11
-		x11-libs/libXcursor
-		x11-libs/libXfixes
-		x11-libs/libXinerama
-		!cairo? (
-			media-libs/fontconfig
-			x11-libs/libXft
-			x11-libs/libXrender
-		)
-	)
-	cairo? (
-		dev-libs/glib:2
-		x11-libs/cairo
-		x11-libs/pango[X?]
-	)
-	opengl? (
-		media-libs/glu
-		media-libs/libglvnd[X]
-	)
-	wayland? (
-		dev-libs/wayland
-		gui-libs/libdecor
-		sys-apps/dbus
-		x11-libs/libxkbcommon
-	)
-"
-DEPEND="
-	${RDEPEND}
-	X? ( x11-base/xorg-proto )
-	wayland? ( dev-libs/wayland-protocols )
-"
-BDEPEND="
-	doc? ( app-text/doxygen )
-	wayland? ( dev-util/wayland-scanner )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.4.1-fltk-config.patch
-	"${FILESDIR}"/${PN}-1.4.1-tests-odr.patch
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# fluid can optionally use html docs at runtime, adjust path
-	sed -i "s|\${FLTK_DOCDIR}/fltk|&-${PVR}/html|" CMake/export.cmake || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DFLTK_BACKEND_WAYLAND=$(usex wayland)
-		-DFLTK_BACKEND_X11=$(usex X)
-		-DFLTK_BUILD_FLUID=yes
-		-DFLTK_BUILD_FLUID_DOCS=no
-		-DFLTK_BUILD_GL=$(usex opengl)
-		-DFLTK_BUILD_HTML_DOCS=$(usex doc)
-		-DFLTK_BUILD_PDF_DOCS=no
-		-DFLTK_BUILD_SHARED_LIBS=yes
-		-DFLTK_BUILD_TEST=$(usex test)
-		-DFLTK_GRAPHICS_CAIRO=$(usex cairo)
-		-DFLTK_OPTION_STD=yes # will be removed & forced ON in fltk-1.5
-	)
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile all $(usev doc docs)
-}
-
-src_test() {
-	# same that upstream's CI does except with the shared version
-	edo "${BUILD_DIR}"/bin/test/unittests-shared --core
-}
-
-src_install() {
-	local DOCS=(
-		ANNOUNCEMENT CHANGES* CREDITS.txt README*
-		$(usev examples)
-		# simpler than using -DFLTK_INSTALL_HTML_DOCS for the location
-		$(usev doc "${BUILD_DIR}"/documentation/html)
-	)
-	cmake_src_install
-
-	# currently no option to disable building static libs
-	use static-libs || rm -- "${ED}"/usr/$(get_libdir)/*.a || die
-}