media-libs/openal: drop 1.24.2

Bug: https://bugs.gentoo.org/955274
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

media-libs/openal/Manifest

@@ -1,2 +1 @@
-DIST openal-soft-1.24.2.tar.bz2 1020760 BLAKE2B d87b470570006b0e3b9f6662ba50db67eb154713d13968e05015f70c12a73f6199cfe13cbe6fd9797081c970cc37e1de1680ecf2606015d09b8eedc27abcc343 SHA512 5ac05fb20b414dfe50e6ac80a69d1e36db5588fd2ccef2606ae1f3b6fc155881d45826031660123101a31469e24bc2bea42993d81b28dd5f18d0d0463988fa65
 DIST openal-soft-1.24.3.tar.bz2 1025568 BLAKE2B 90a2f60b7d8d1d13f9013b6371500317ab152bc467843d23411d34b2ccb1243f1d9ad06e371b8ec3a4bf85985a2dc5dcd51edf4539b5e07d5e1053da27a5b0c0 SHA512 fab41a031f0f52aa0d5803d22722084885c1dd43727895ccd090b29fd3476621a97a5031b21e507d5175372dca910450b728a04fc65857698e1296831db8a6fe

media-libs/openal/openal-1.24.2.ebuild

@@ -1,87 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# False positives because of REQUIRE vs BACKEND options() (conditionally set)
-# See bug #809314
-CMAKE_WARN_UNUSED_CLI=no
-inherit cmake-multilib
-
-MY_P="${PN}-soft-${PV}"
-
-DESCRIPTION="A software implementation of the OpenAL 3D audio API"
-HOMEPAGE="https://www.openal-soft.org/"
-SRC_URI="https://www.openal-soft.org/openal-releases/${MY_P}.tar.bz2"
-S="${WORKDIR}"/${MY_P}
-
-# See https://github.com/kcat/openal-soft/blob/e0097c18b82d5da37248c4823fde48b6e0002cdd/BSD-3Clause
-# Some components are under BSD
-LICENSE="LGPL-2+ BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
-IUSE="
-	alsa coreaudio debug jack oss pipewire portaudio pulseaudio sdl sndio qt5
-	cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1
-	cpu_flags_arm_neon
-"
-
-# PipeWire:
-# - See bug #863200 for PipeWire minimum version
-# - PW is in DEPEND although not linked against because we need configure to
-# find it anyway, but no :=.
-RDEPEND="
-	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
-	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
-	pipewire? ( media-video/pipewire[${MULTILIB_USEDEP}] )
-	portaudio? ( media-libs/portaudio[${MULTILIB_USEDEP}] )
-	pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-	)
-	sdl? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
-	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
-"
-DEPEND="
-	${RDEPEND}
-	oss? ( virtual/os-headers )
-"
-
-DOCS=( alsoftrc.sample docs/env-vars.txt docs/hrtf.txt ChangeLog README.md )
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		# See bug #809314 for getting both options for backends
-		-DALSOFT_{BACKEND,REQUIRE}_ALSA=$(usex alsa)
-		-DALSOFT_{BACKEND,REQUIRE}_COREAUDIO=$(usex coreaudio)
-		-DALSOFT_{BACKEND,REQUIRE}_JACK=$(usex jack)
-		-DALSOFT_{BACKEND,REQUIRE}_OSS=$(usex oss)
-		-DALSOFT_{BACKEND,REQUIRE}_PIPEWIRE=$(usex pipewire)
-		-DALSOFT_{BACKEND,REQUIRE}_PORTAUDIO=$(usex portaudio)
-		-DALSOFT_{BACKEND,REQUIRE}_PULSEAUDIO=$(usex pulseaudio)
-		-DALSOFT_{BACKEND,REQUIRE}_SDL2=$(usex sdl)
-		-DALSOFT_{BACKEND,REQUIRE}_SNDIO=$(usex sndio)
-
-		-DALSOFT_UTILS=$(multilib_is_native_abi && echo "ON" || echo "OFF")
-		-DALSOFT_NO_CONFIG_UTIL=$(usex qt5 "$(multilib_is_native_abi && echo "OFF" || echo "ON")" ON)
-		 # EXAMPLES=OFF to avoid FFmpeg dependency, bug #481670
-		-DALSOFT_EXAMPLES=OFF
-	)
-
-	# Avoid unused variable warnings, bug #738240
-	if use amd64 || use x86 ; then
-		mycmakeargs+=(
-			-DALSOFT_CPUEXT_SSE=$(usex cpu_flags_x86_sse)
-			-DALSOFT_CPUEXT_SSE2=$(usex cpu_flags_x86_sse2)
-			-DALSOFT_CPUEXT_SSE4_1=$(usex cpu_flags_x86_sse4_1)
-		)
-	elif use arm || use arm64 ; then
-		mycmakeargs+=(
-			-DALSOFT_CPUEXT_NEON=$(usex cpu_flags_arm_neon)
-		)
-	fi
-
-	cmake_src_configure
-}