mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
app-i18n/ibus: version bump 1.5.24
Closes: https://bugs.gentoo.org/793698 Package-Manager: Portage-3.0.19, Repoman-3.0.3 Signed-off-by: Yixun Lan <dlan@gentoo.org>
This commit is contained in:
Yixun Lan
@@ -1,3 +1,4 @@
|
||||
DIST ibus-1.5.22.tar.gz 3578251 BLAKE2B 08ad72bd455d2841700b11a4ade88e2b9768433f86bac4baf20db882580b10a4705f545a845a03d3b4196a75c43d33c51ffd31a3516d71030f891ce48dce69c2 SHA512 0abe89acc6da8cea484a6b9f807c08e94869072f374f9e8f4541a426636f818f1c3cb8b9237f97245771f9e4bf19184983d8ac924177dc4824ca6e8b5304425d
|
||||
DIST ibus-1.5.23-gentoo-patches-1.tar.xz 1596 BLAKE2B 5a2c084cb25cb35d16eba8e6953c1ffc249875ab11485a675497f04a4366ea3fe216bab3407f390a0330f4f17cf5a70a43547160cc9c29a6b14890fcb7867456 SHA512 a1c2a77dbc4185c3658c36b998c9d925fff2bbeb9bc5fde5c74c62081056f134875d557ba0b4af7b06d56f004975889f453adea623541d3bfff2c391912efa05
|
||||
DIST ibus-1.5.23.tar.gz 3557661 BLAKE2B 4cfb3287c80d46e55090d4f361dd977f4be5988a8b7ffc24755954090dc25021ea6cbb6798769494e6cd70267aac6daa238fdc7cf4156296d93f79f325a18ac4 SHA512 4ea66d0a7203d665fb5c90e59ddf294614feeafc4f06b10e35989671a9bf39d5977e9061b9be224cd5a9439ac2f697a4326ff221ae868f5ebed46cbb09e9a205
|
||||
DIST ibus-1.5.24.tar.gz 3614372 BLAKE2B 4b851ed9dc8283bf58957adfd5dd4bf7da8b019f95055dbbf7fa157502b3dcc11d561881ff6afa5db0b83b4e7d82f3bd228cd0e21ff77cb81b1eaca246deb135 SHA512 25f34a51a5c85352e61699ca36bf7ddb9b486b28d71e15ce3a52b78bc9db2f8cb558049e0652fdc5431215a5f826fcb5a7d5e44f0de9a2ff746aaf60672e2f22
|
||||
|
||||
190
app-i18n/ibus/ibus-1.5.24.ebuild
Normal file
190
app-i18n/ibus/ibus-1.5.24.ebuild
Normal file
@@ -0,0 +1,190 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
PYTHON_COMPAT=( python{3_7,3_8,3_9} )
|
||||
VALA_MIN_API_VERSION="0.34"
|
||||
VALA_MAX_API_VERSION="0.50"
|
||||
VALA_USE_DEPEND="vapigen"
|
||||
|
||||
inherit autotools bash-completion-r1 gnome2-utils python-r1 vala virtualx xdg-utils
|
||||
|
||||
GENTOO_VER=
|
||||
DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
|
||||
HOMEPAGE="https://github.com/ibus/ibus/wiki"
|
||||
|
||||
[[ -n ${GENTOO_VER} ]] && \
|
||||
GENTOO_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${P}-gentoo-patches-${GENTOO_VER}.tar.xz"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz
|
||||
${GENTOO_PATCHSET_URI}"
|
||||
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
|
||||
IUSE="+X +emoji +gtk +gtk2 +introspection kde nls +python test +unicode vala wayland"
|
||||
RESTRICT="!test? ( test )"
|
||||
REQUIRED_USE="emoji? ( gtk )
|
||||
gtk2? ( gtk )
|
||||
kde? ( gtk )
|
||||
python? (
|
||||
${PYTHON_REQUIRED_USE}
|
||||
introspection
|
||||
)
|
||||
test? ( gtk )
|
||||
vala? ( introspection )"
|
||||
|
||||
CDEPEND="app-text/iso-codes
|
||||
dev-libs/glib:2
|
||||
gnome-base/dconf
|
||||
gnome-base/librsvg:2
|
||||
sys-apps/dbus[X?]
|
||||
X? (
|
||||
x11-libs/libX11
|
||||
!gtk? ( x11-libs/gtk+:2 )
|
||||
)
|
||||
gtk? (
|
||||
x11-libs/gtk+:3
|
||||
x11-libs/libX11
|
||||
x11-libs/libXi
|
||||
gtk2? ( x11-libs/gtk+:2 )
|
||||
)
|
||||
introspection? ( dev-libs/gobject-introspection )
|
||||
kde? ( dev-qt/qtgui:5 )
|
||||
nls? ( virtual/libintl )
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
dev-python/pygobject:3[${PYTHON_USEDEP}]
|
||||
)
|
||||
wayland? (
|
||||
dev-libs/wayland
|
||||
x11-libs/libxkbcommon
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
python? (
|
||||
gtk? (
|
||||
x11-libs/gtk+:3[introspection]
|
||||
)
|
||||
)"
|
||||
DEPEND="${CDEPEND}
|
||||
$(vala_depend)
|
||||
dev-util/glib-utils
|
||||
virtual/pkgconfig
|
||||
x11-misc/xkeyboard-config
|
||||
emoji? (
|
||||
app-i18n/unicode-cldr
|
||||
app-i18n/unicode-emoji
|
||||
)
|
||||
nls? ( sys-devel/gettext )
|
||||
unicode? ( app-i18n/unicode-data )"
|
||||
|
||||
src_prepare() {
|
||||
vala_src_prepare --ignore-use
|
||||
sed -i "/UCD_DIR=/s/\$with_emoji_annotation_dir/\$with_ucd_dir/" configure.ac
|
||||
if ! has_version 'x11-libs/gtk+:3[wayland]'; then
|
||||
touch ui/gtk3/panelbinding.vala
|
||||
fi
|
||||
if ! use emoji; then
|
||||
touch \
|
||||
tools/main.vala \
|
||||
ui/gtk3/panel.vala
|
||||
fi
|
||||
if ! use kde; then
|
||||
touch ui/gtk3/panel.vala
|
||||
fi
|
||||
if [[ -n ${GENTOO_VER} ]]; then
|
||||
einfo "Try to apply Gentoo specific patch set"
|
||||
eapply "${WORKDIR}"/patches-gentoo/*.patch
|
||||
fi
|
||||
|
||||
# for multiple Python implementations
|
||||
sed -i "s/^\(PYGOBJECT_DIR =\).*/\1/" bindings/Makefile.am
|
||||
# fix for parallel install
|
||||
sed -i "/^if ENABLE_PYTHON2/,/^endif/d" bindings/pygobject/Makefile.am
|
||||
# require user interaction
|
||||
sed -i "/^TESTS += ibus-\(compose\|keypress\)/d" src/tests/Makefile.am
|
||||
|
||||
sed -i "/^bash_completion/d" tools/Makefile.am
|
||||
|
||||
default
|
||||
eautoreconf
|
||||
xdg_environment_reset
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local unicodedir="${EPREFIX}"/usr/share/unicode
|
||||
local python_conf=()
|
||||
if use python; then
|
||||
python_setup
|
||||
python_conf+=(
|
||||
$(use_enable gtk setup)
|
||||
--with-python=${EPYTHON}
|
||||
)
|
||||
else
|
||||
python_conf+=( --disable-setup )
|
||||
fi
|
||||
|
||||
econf \
|
||||
$(use_enable X xim) \
|
||||
$(use_enable emoji emoji-dict) \
|
||||
$(use_with emoji unicode-emoji-dir "${unicodedir}"/emoji) \
|
||||
$(use_with emoji emoji-annotation-dir "${unicodedir}"/cldr/common/annotations) \
|
||||
$(use_enable gtk gtk3) \
|
||||
$(use_enable gtk ui) \
|
||||
$(use_enable gtk2) \
|
||||
$(use_enable introspection) \
|
||||
$(use_enable kde appindicator) \
|
||||
$(use_enable nls) \
|
||||
$(use_enable test tests) \
|
||||
$(use_enable unicode unicode-dict) \
|
||||
$(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data") \
|
||||
$(use_enable vala) \
|
||||
$(use_enable wayland) \
|
||||
"${python_conf[@]}"
|
||||
}
|
||||
|
||||
src_test() {
|
||||
unset DBUS_SESSION_BUS_ADDRESS
|
||||
virtx emake -j1 check
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
find "${ED}" -name '*.la' -delete || die
|
||||
|
||||
if use python; then
|
||||
python_install() {
|
||||
emake -C bindings/pygobject \
|
||||
pyoverridesdir="$(${EPYTHON} -c 'import gi; print(gi._overridesdir)')" \
|
||||
DESTDIR="${D}" \
|
||||
install
|
||||
|
||||
python_optimize
|
||||
}
|
||||
python_foreach_impl python_install
|
||||
fi
|
||||
|
||||
keepdir /usr/share/ibus/engine
|
||||
|
||||
newbashcomp tools/${PN}.bash ${PN}
|
||||
|
||||
insinto /etc/X11/xinit/xinput.d
|
||||
newins xinput-${PN} ${PN}.conf
|
||||
|
||||
# Undo compression of man page
|
||||
find "${ED}"/usr/share/man -type f -name '*.gz' -exec gzip -d {} \; || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use gtk && gnome2_query_immodules_gtk3
|
||||
use gtk2 && gnome2_query_immodules_gtk2
|
||||
xdg_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
dconf update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use gtk && gnome2_query_immodules_gtk3
|
||||
use gtk2 && gnome2_query_immodules_gtk2
|
||||
xdg_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
}
|
||||
Reference in New Issue
Block a user