media-sound/guitarix: Version bump to 0.42.1

* EAPI 7 bump
* reorganize dependencies
* support python3.9

Signed-off-by: Alexander Tsoy <alexander@tsoy.me>
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
This commit is contained in:
Alexander Tsoy
2020-12-30 07:28:01 +01:00
committed by Miroslav Šulc
parent eb940ff5f3
commit 955f39d25e
2 changed files with 91 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST guitarix2-0.41.0.tar.xz 70865716 BLAKE2B d3caa51f297153c16df624ababaffc1405ddb10f04ae01672720bb2229d4be3426b33f75021b1862f996fb09466eaad008f748b42cb8382f08d14e23758cfc9b SHA512 27fe6f2b87c8913feafae1c17472150d37df46ed3437b033cd22f509edf67420fb8f4024e404d5bec901a687dbe948acda702bf37cb0c738feb5b3b8e5ebb8aa
DIST guitarix2-0.42.1.tar.xz 71825372 BLAKE2B 06b2a19d68e77c622eea222e3f0658d9f89c6c8377e9b0442d581e14342f82f97948ca0ebb7ff40f4abd6cab0c9ba582fa6f43f74cad5e112d2e762445f2ab43 SHA512 66a71b4d66e0cbcff7feeceae6317c016e497626c9fde3ca44e1f06e42d9021b2857151660c1c49832cc8e6f2aa27de68dfea67d4e896c7e89f84865f8ba1eb0
@@ -0,0 +1,90 @@
# Copyright 2019-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8,9} )
PYTHON_REQ_USE='threads(+)'
inherit python-any-r1 waf-utils xdg
MY_P="${PN}2-${PV}"
DESCRIPTION="Virtual guitar amplifier for Linux"
HOMEPAGE="https://guitarix.org/"
SRC_URI="mirror://sourceforge/guitarix/guitarix/${MY_P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="bluetooth debug lv2 nls nsm +standalone zeroconf"
REQUIRED_USE="|| ( lv2 standalone )"
DEPEND="
dev-cpp/eigen:3
dev-cpp/glibmm:2
dev-cpp/gtkmm:3.0
dev-libs/glib:2
>=media-libs/libsndfile-1.0.17
>=media-libs/zita-convolver-3:=
media-libs/zita-resampler
>=net-misc/curl-7.26.0
>=sci-libs/fftw-3.3.8:3.0=
x11-libs/gtk+:3
lv2? ( media-libs/lv2 )
standalone? (
dev-libs/boost:=
media-libs/liblrdf
media-libs/lilv
virtual/jack
bluetooth? ( net-wireless/bluez )
nsm? ( media-libs/liblo )
zeroconf? ( net-dns/avahi )
)
"
# roboto fonts are required for correct ui rendering
RDEPEND="
${DEPEND}
standalone? (
media-fonts/roboto
)
"
BDEPEND="
${PYTHON_DEPS}
virtual/pkgconfig
standalone? (
dev-lang/sassc
nls? (
dev-util/intltool
sys-devel/gettext
)
)
"
DOCS=( changelog README )
PATCHES=(
"${FILESDIR}"/${PN}-0.41.0-nostrip.patch
)
src_configure() {
local myconf=(
--cxxflags-debug=""
--cxxflags-release="-DNDEBUG"
--ldflags="${LDFLAGS}"
--enable-lfs
--lib-dev
--no-desktop-update
--no-faust
--no-ldconfig
--shared-lib
$(use_enable nls)
$(usex bluetooth "" "--no-bluez")
$(usex debug "--debug" "")
$(usex lv2 "--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2" "--no-lv2 --no-lv2-gui")
$(usex nsm "" "--no-nsm")
$(usex standalone "" "--no-standalone")
$(usex zeroconf "" "--no-avahi")
)
waf-utils_src_configure "${myconf[@]}"
}