media-gfx/simple-scan: add 49.1

Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://github.com/gentoo/gentoo/pull/44620
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

media-gfx/simple-scan/Manifest

@@ -1 +1,2 @@
 DIST simple-scan-46.0.tar.xz 1136672 BLAKE2B 0ee2dd5392ed1a888948183e9efbd8943287baad66dd45351cbbb32a9a4c17903415676b3e6e00203d8a3572e90397b51bc23ecec2ad6cfa6597a10ffdd5bcf4 SHA512 f7c4433536f59c71f066cdae51b0de1b0dcf9b8af00f3bedb4c1be281d09f9ce122666ed849bd88de8868042429f14bb7b01409f8a006360ce4285000fd30bdc
+DIST simple-scan-49.1.tar.xz 1216808 BLAKE2B 9e1bb19d8f0812ee574435b5e681056c1c0f5bcf8cd9c9881f367ae5c7fe67a52c029881b7bd8b235a18a072cdada17bf287c512ae5c29ece461eb31a9dbc70a SHA512 3f67928cca7019adaee58b71b40fda9dca232c42375e9d578d9c460f47b209e011d979360210304e859101cf043c048ff42f9365a0c69e7c8e78813c75c984a6

media-gfx/simple-scan/simple-scan-49.1.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..13} )
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="colord webp"
+
+DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=gui-libs/gtk-4.10.0:4
+	>=gui-libs/libadwaita-1.2.0:1
+	>=virtual/zlib-1.2.3.1:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/libgusb-0.2.7
+	colord? ( >=x11-misc/colord-0.1.24:=[udev(+)] )
+	webp? ( media-libs/libwebp:= )
+	>=media-gfx/sane-backends-1.0.20
+"
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gui-libs/libadwaita:1[vala]
+	dev-libs/libgusb[vala]
+	colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+	# Add control for optional dependencies
+	"${FILESDIR}"/46.0-add-control-optional-deps.patch
+)
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord)
+		-Dpackagekit=false
+		$(meson_use webp)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}