dev-python/paramiko: Bump to 2.10.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/paramiko/Manifest

@@ -1 +1,2 @@
+DIST paramiko-2.10.1.tar.gz 347426 BLAKE2B 5c277afb2c8483a522756d017092174d5fc88e534a0069362be26b81896e5c2e280aa06db4d7b945d46f7c3563693f25409d0a51ba184e43d982b5276a76c5fe SHA512 1d97f32c0c14229cf51c2762fe2552ca3ac9bfd945965702cecbcf1ff62f1e740f7fb048d74127230ae23bd4b6ada8509da67e1c1da6a38d65254e674f054f6c
 DIST paramiko-2.9.2.tar.gz 345088 BLAKE2B b3b95ec222ac5386fba311c2f0878a44a92bfd0d6edd45c928e2c681fccaf66f2bcfb185cf3eafd37361dc119127623d2c690a981e9f30bfe280eb4c1a0f66e6 SHA512 5b0810358376e4a42ba38ffa4a713f104b122fd77d463a80937dd6dc529da70825d6741fec16f93071aefe4bbfa6f0dbdb2eabd125663c19ba4d35ac06ecfa90

dev-python/paramiko/paramiko-2.10.1.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="SSH2 protocol library"
+HOMEPAGE="https://www.paramiko.org/ https://github.com/paramiko/paramiko/ https://pypi.org/project/paramiko/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris"
+IUSE="examples server"
+
+RDEPEND="
+	>=dev-python/bcrypt-3.1.3[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.5[${PYTHON_USEDEP}]
+	>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx sites/docs
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-2.7.1-tests.patch"
+	)
+
+	if ! use server; then
+		PATCHES+=( "${FILESDIR}/${PN}-2.4.2-disable-server.patch" )
+	fi
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r demos/*
+	fi
+}