dev-python/kazoo: Enable tests

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/kazoo/kazoo-2.7.0-r1.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_6 python3_7 python3_8 )
+
+inherit distutils-r1
+
+DESCRIPTION="A high-level Python library that makes it easier to use Apache Zookeeper"
+HOMEPAGE="https://kazoo.readthedocs.org/ https://github.com/python-zk/kazoo/ https://pypi.org/project/kazoo/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/graphviz[${PYTHON_USEDEP}]
+		>=dev-python/objgraph-3.4.0[${PYTHON_USEDEP}]
+		sys-cluster/zookeeper-bin
+	)
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests setup.py
+
+src_prepare() {
+	# TODO
+	sed -e 's:test_basic_commands:_&:' \
+		-e 's:test_data_watcher:_&:' \
+		-i kazoo/tests/test_gevent_handler.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	local pkgver=$(best_version sys-cluster/zookeeper-bin)
+	export ZOOKEEPER_VERSION=${pkgver##*-}
+	export ZOOKEEPER_PATH=${BROOT}/opt/zookeeper-bin
+	distutils-r1_src_test
+}
+
+python_install_all() {
+	local DOCS=( {CHANGES,CONTRIBUTING,README}.md )
+	distutils-r1_python_install_all
+}