dev-python/magic-wormhole: Bump to 0.17.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/magic-wormhole/Manifest

@@ -1 +1,2 @@
 DIST magic-wormhole-0.16.0.tar.gz 283219 BLAKE2B a99b4ed779af7bed39df18a1c2eaab76fab6f7966938cbd8db55ce89353c1e89193b46d09599477266a5e5d5c52f19965f412e74ae0f8ab0d32ec47184319cb0 SHA512 c0cb8391e14bb34874f099646bb8bd80f812030f365e590915ddb50217b4717bb0ddfff3edc4694007d9c79b209045c6ca621a2890d65680146087b47bee8fd8
+DIST magic_wormhole-0.17.0.tar.gz 284056 BLAKE2B f8bd45be5fca5015c7c0b601512ba823025d164172368f60309b74d078dead0f0b7a67bd548974811279728210bee542de1bbd6d7e8e3b568115e8b1d72795ac SHA512 12866b544b375b29cf2f58c59aa0e65000cfae0025b5e7a773b1f57a35c98b38629aaec9cc30cf4232f745b76db642e8bd15c41e8d8ba1a8e112c50b33293eff

dev-python/magic-wormhole/magic-wormhole-0.17.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Get Things From One Computer To Another, Safely"
+HOMEPAGE="
+	https://magic-wormhole.readthedocs.io/en/latest/
+	https://github.com/magic-wormhole/magic-wormhole/
+	https://pypi.org/project/magic-wormhole/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/autobahn-0.14.1[${PYTHON_USEDEP}]
+	dev-python/automat[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	>=dev-python/iterable-io-1.0.0[${PYTHON_USEDEP}]
+	dev-python/noiseprotocol[${PYTHON_USEDEP}]
+	dev-python/pynacl[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	~dev-python/spake2-0.9[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4.13.0[${PYTHON_USEDEP}]
+	dev-python/twisted[ssl,${PYTHON_USEDEP}]
+	>=dev-python/txtorcon-18.0.2[${PYTHON_USEDEP}]
+	>=dev-python/zipstream-ng-1.7.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/magic-wormhole-mailbox-server[${PYTHON_USEDEP}]
+		~dev-python/magic-wormhole-transit-relay-0.3.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm versioneer.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		src/wormhole/test/test_transit.py::InboundConnectionFactory::test_log_other_errors
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp "${ED}/usr/wormhole_complete.bash" wormhole
+	insinto /usr/share/fish/completions
+	newins "${ED}/usr/wormhole_complete.fish" wormhole.fish
+	insinto /usr/share/zsh/site-functions
+	newins "${ED}/usr/wormhole_complete.zsh" _wormhole
+	rm "${ED}/usr"/wormhole_complete* || die
+}