x11-plugins/astime: new EAPI=6 revision that respects LDFLAGS.

This new revision is based on the ebuild submitted by Michael
Mair-Keimberger, with additional updates for EAPI=6. I have also
simplified the patch that we apply; now it contains only the addition
of LDFLAGS to the linker command. By side-stepping upstream's "make
install" target, we avoid having to patch in DESTDIR and all of that.
Doing so actually simplifies src_install() a bit, as it can be reduced
to a dobin, newman, and dodoc.

Gentoo-Bug: 337428

Package-Manager: portage-2.2.28

x11-plugins/astime/astime-2.8-r2.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Analogue clock utility for X Windows"
+HOMEPAGE="http://www.tigr.net/"
+SRC_URI="${HOMEPAGE}afterstep/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="jpeg"
+
+RDEPEND="x11-libs/libXpm
+	x11-libs/libSM
+	jpeg? ( virtual/jpeg:0 )"
+
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+PATCHES=( "${FILESDIR}/respect-ldflags.patch" )
+
+src_configure() {
+	econf $(use_enable jpeg)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install () {
+	dobin "${PN}"
+	newman "${PN}.man" "${PN}.1"
+	einstalldocs
+}

x11-plugins/astime/files/respect-ldflags.patch

@@ -0,0 +1,11 @@
+--- a/autoconf/Makefile.common.in	1999-05-02 17:12:39.000000000 +0200
++++ b/autoconf/Makefile.common.in	2013-03-24 16:16:27.494987496 +0100
+@@ -34,7 +33,7 @@
+ 		done
+ 
+ $(PROG):        $(OBJS)
+-		$(CC) $(OBJS) $(LIBRARIES) $(EXTRA_LIBRARIES) -o $(@)
++		$(CC) $(OBJS) $(LIBRARIES) $(EXTRA_LIBRARIES) -o $(@) $(LDFLAGS)
+ 
+ .c.o:
+ 		$(CC) $(CCFLAGS) $(EXTRA_DEFINES) $(INCLUDES) $(EXTRA_INCLUDES) -c $*.c