kde-apps/dolphin-plugins-subversion: 20.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2021-03-04 22:27:56 +01:00
parent 89d041f662
commit 933f4e6e77
2 changed files with 66 additions and 0 deletions
@@ -1,2 +1,3 @@
DIST dolphin-plugins-20.08.3.tar.xz 230272 BLAKE2B 1978ffebe88d95350cac0892c56e127507b6ddd6d5675bca8f420990552e20ff271e6f5742a2bdeff685c82464e70177ac83e5e9368547eb175a3e8133d77624 SHA512 2010be567ef025375caac92e90c0259faea1eb58bdbc55e441e42a10af68b6313391707a7f6b6b10285ba80dcbdee92468fa5088970eb98d4ea8afea145976d9
DIST dolphin-plugins-20.12.2.tar.xz 239368 BLAKE2B 638491ab7e97768bfe99e8eea47d34721f9d952ff9a5c236b7ac71862d3912bf10afca67dc5e5e8e8b5f8f3b6c6eafa2e7dadea0e089ca1296078694dd4d069c SHA512 b6d160c7aadddb332ef8d5440ef8171668a24e44eb837918557016272ad5e2e51456fcb2e155c93507737e341596c89621bdd0a35ac1d5f81e79afcfa89cd3ff
DIST dolphin-plugins-20.12.3.tar.xz 239340 BLAKE2B 141e5d2bb6190edaef98cec2a271e41b916966118300d69f4eb5e7da15e51730476f23a20312b76fca0fc1490501e83528b4f0cb62f9f6c64e4caf5ac5b2cd37 SHA512 1d5303e92d912bc80c5260263b081205d36372f1f15205ebd3e705697a114f8481edd1ad31004d7906c3088d43a74cb1e33dac6e1196c247e702a544d67db11b
@@ -0,0 +1,65 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="false"
KDE_ORG_NAME="dolphin-plugins"
MY_PLUGIN_NAME="svn"
PVCUT=$(ver_cut 1-3)
KFMIN=5.75.0
QTMIN=5.15.2
inherit ecm kde.org
DESCRIPTION="Dolphin plugin for Subversion integration"
HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE=""
DEPEND="
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-apps/dolphin-${PVCUT}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
"
RDEPEND="${DEPEND}
dev-vcs/subversion
>=kde-apps/kompare-${PVCUT}:5
"
src_prepare() {
ecm_src_prepare
# solid, qtdbus only required by mountiso
ecm_punt_bogus_dep Qt5 DBus
ecm_punt_bogus_dep KF5 Solid
# kxmlgui, qtnetwork only required by dropbox
ecm_punt_bogus_dep Qt5 Network
ecm_punt_bogus_dep KF5 XmlGui
# delete non-${PN} translations
if [[ ${KDE_BUILD_TYPE} = release ]]; then
find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
fi
}
src_configure() {
local mycmakeargs=(
-DBUILD_${MY_PLUGIN_NAME}=ON
-DBUILD_bazaar=OFF
-DBUILD_dropbox=OFF
-DBUILD_git=OFF
-DBUILD_hg=OFF
-DBUILD_mountiso=OFF
)
ecm_src_configure
}
src_install() {
ecm_src_install
rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
}