dev-python/spyder-kernels: Bump to 3.0.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/spyder-kernels/Manifest

@@ -1 +1,2 @@
 DIST spyder-kernels-3.0.3.gh.tar.gz 240072 BLAKE2B 99fe0e7ecae61b717ce0215a6789742ed5f684fcc700d911388c4ca481e37dee829014b1b1633ba110a669bba3636ef250f94777d8c501f682c4fb53288e469f SHA512 4335c0401da8cc0a13db2888acf740e20ec9c21ad29b9375806b0958b81649623cd672f2d4579059b083fba11ec1e42acc28c0da76c3f7d3c0510b64006d32c7
+DIST spyder-kernels-3.0.4.gh.tar.gz 240281 BLAKE2B 32ebf1e22dc354236bfc307d6b273e97a4ec2a0fcbdb24b3c3d43e218f0200d17d65d69e0c210d916ed91925ec655122f4ec9174b4834f8e67e48bac962ba544 SHA512 3336a37e1b1c9dfec82ec99956e0cbcada0ed45670e7f76037a48f094682eb56dfe13d3e1cb046487594bd474fa2210ea5362c94dd57b7c39e72ec43599acfa8

dev-python/spyder-kernels/spyder-kernels-3.0.4.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Kernels used by spyder on its ipython console"
+HOMEPAGE="
+	https://github.com/spyder-ide/spyder-kernels/
+	https://pypi.org/project/spyder-kernels/
+"
+SRC_URI="https://github.com/spyder-ide/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.29.3[${PYTHON_USEDEP}]
+	>=dev-python/ipython-8.13.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-client-9[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.9[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/h5py[${PYTHON_USEDEP}]
+			dev-python/pandas[${PYTHON_USEDEP}]
+			dev-python/xarray[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin ipython, all tests pass
+	sed -i -e '/ipython/s:,<9::' setup.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# we no longer package distributed, and also removed dependency on dask
+		spyder_kernels/console/tests/test_console_kernel.py::test_dask_multiprocessing
+
+		# RuntimeError: There is no current event loop in thread 'MainThread'.
+		# https://bugs.gentoo.org/834893
+		spyder_kernels/console/tests/test_console_kernel.py::test_cwd_in_sys_path
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing_2
+		spyder_kernels/console/tests/test_console_kernel.py::test_runfile
+		spyder_kernels/console/tests/test_console_kernel.py::test_np_threshold
+		spyder_kernels/console/tests/test_console_kernel.py::test_turtle_launch
+		spyder_kernels/console/tests/test_console_kernel.py::test_matplotlib_inline
+
+		# pydicom only packaged in ::sci at the moment
+		spyder_kernels/utils/tests/test_iofuncs.py::test_load_dicom_files
+	)
+	local EPYTEST_IGNORE=()
+
+	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			# require pandas
+			spyder_kernels/utils/tests/test_nsview.py
+		)
+	fi
+
+	if ! has_version "dev-python/h5py[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# require hdf5
+			spyder_kernels/utils/tests/test_iofuncs.py::test_save_load_hdf5_files
+			spyder_kernels/utils/tests/test_dochelpers.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}