app-containers/cri-o: drop 1.24.1

Bug: https://bugs.gentoo.org/870937
Signed-off-by: Zac Medico <zmedico@gentoo.org>

app-containers/cri-o/Manifest

@@ -1,2 +1 @@
-DIST cri-o-1.24.1.tar.gz 15943809 BLAKE2B 13840967b7555e680652cdfe71e358fee5afcfbdbc28771960a5e28c88d6242909a595212559b7967c05cfc7cf9921d6d227b810a26bdc66cb75ffed917bcb23 SHA512 899efb61c70be3a0e950dc239245e1a4dca66e2130d8b355a7ad73c1e91088a2d42c6a4cc05f879cc6a1252d40294e9a8845fd2b110148a05a9d63f61077c498
 DIST cri-o-1.25.0.tar.gz 27673668 BLAKE2B 5231f1b00781233ddf82827a580100055fefb97e768d871a845506ee28ebc122f20f6c8dff64b9dd8d991ed6ed761a72e96d607354f7e8d4182daff36ef3c253 SHA512 783c2f019ef65079dbb838e58acde5a24bda282ba8298d7b95491356e46fc208a14bcc4c65e3183001f0fb275d8ec5d7b5c795300e6424096f84fb9130721cba

app-containers/cri-o/cri-o-1.24.1.ebuild

@@ -1,101 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-EGIT_COMMIT=a3bbde8a77c323aa6a485da9a9046299155c6016
-
-inherit go-module
-
-DESCRIPTION="OCI-based implementation of Kubernetes Container Runtime Interface"
-HOMEPAGE="https://cri-o.io/"
-SRC_URI="https://github.com/cri-o/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT MPL-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-IUSE="btrfs +device-mapper selinux systemd"
-
-COMMON_DEPEND="
-	app-crypt/gpgme:=
-	app-containers/conmon
-	app-containers/runc
-	dev-libs/glib:=
-	dev-libs/libassuan:=
-	dev-libs/libgpg-error:=
-	net-firewall/conntrack-tools
-	net-firewall/iptables
-	app-containers/cni-plugins
-	net-misc/socat
-	sys-apps/iproute2
-	sys-libs/libseccomp:=
-	btrfs? ( sys-fs/btrfs-progs )
-	device-mapper? ( sys-fs/lvm2:= )
-	selinux? ( sys-libs/libselinux:= )
-	systemd? ( sys-apps/systemd:= )"
-DEPEND="
-	${COMMON_DEPEND}
-	dev-go/go-md2man"
-RDEPEND="${COMMON_DEPEND}
-	!<app-containers/podman-1.3.2-r1"
-
-src_prepare() {
-	default
-
-	sed -e '/^export GOPROXY=/d' \
-		-e '/^GIT_.*/d' \
-		-e '/	git diff --exit-code/d' \
-		-e 's/$(GO) build -i/$(GO) build -v -work -x/' \
-		-e 's/\${GIT_COMMIT}/'${EGIT_COMMIT}'/' \
-		-e "s|^GIT_COMMIT := .*|GIT_COMMIT := ${EGIT_COMMIT}|" \
-		-e "s|^COMMIT_NO := .*|COMMIT_NO := ${EGIT_COMMIT}|" \
-		-i Makefile || die
-
-	echo ".NOTPARALLEL: binaries docs" >> Makefile || die
-
-	sed -e 's:/usr/local/bin:/usr/bin:' \
-		-i contrib/systemd/* || die
-}
-
-src_compile() {
-	[[ -f hack/btrfs_installed_tag.sh ]] || die
-	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
-		hack/btrfs_installed_tag.sh || die; }
-
-	[[ -f hack/libdm_installed.sh ]] || die
-	use device-mapper || { echo -e "#!/bin/sh\necho exclude_graphdriver_devicemapper" > \
-		hack/libdm_installed.sh || die; }
-
-	[[ -f hack/selinux_tag.sh ]] || die
-	use selinux || { echo -e "#!/bin/sh\ntrue" > \
-		hack/selinux_tag.sh || die; }
-
-	mkdir -p bin || die
-	emake all \
-		GOBIN="${S}/bin" \
-		GO_BUILD="go build ${GOFLAGS}" \
-		GO_MD2MAN="$(which go-md2man)"
-}
-
-src_install() {
-	emake install install.config install.systemd \
-		DESTDIR="${D}" \
-		GO_MD2MAN="$(which go-md2man)" \
-		PREFIX="${D}${EPREFIX}/usr"
-	keepdir /etc/crio
-	mv "${ED}/etc/crio/crio.conf"{,.example} || die
-
-	newinitd "${FILESDIR}/crio.initd" crio
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
-
-	# Suppress crio log error messages triggered if these don't exist.
-	keepdir /etc/containers/oci/hooks.d
-	keepdir /usr/share/containers/oci/hooks.d
-
-	# Suppress crio "Missing CNI default network" log message.
-	keepdir /etc/cni/net.d
-	insinto /etc/cni/net.d
-	doins contrib/cni/99-loopback.conf
-}