xfce-extra/xfce4-whiskermenu-plugin: Bump to 2.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-whiskermenu-plugin/Manifest

@@ -1 +1,2 @@
 DIST xfce4-whiskermenu-plugin-2.7.3.tar.bz2 180287 BLAKE2B 7433e2bac372666281311109f04bb07b62c884a56a794c0c09bc28e1c80786b4ee10d32deac86d4bdc12c38edca46a355a571f4d7164861898748ef5fd844541 SHA512 a734e54e900d17fa82c53eeab2a2e706481951911640714928b53eb3a06a3b5b3e7292e6869e719345cb5c89d917146ae350db6827ac8fd3bcdb9b4dd2ddce4d
+DIST xfce4-whiskermenu-plugin-2.8.0.tar.bz2 187093 BLAKE2B 8836dbb7691dff9c2abe03e996514b07e73532140f685dd42c7453638a0f7fba2c149553c098e9dfb713e111f14ce21f5738dd338f333fe5a980c0fc2c06ce68 SHA512 844c34ea85e2574dc39e90bb08774c3e7e9e3e13a0a35b1da916d3b3187f158d9f6e130312f2545e26cd214f98cc03461a857ad4c91893febe9942ad08c58a70

xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-2.8.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake xdg-utils
+
+DESCRIPTION="Alternate application launcher for Xfce"
+HOMEPAGE="https://gottcode.org/xfce4-whiskermenu-plugin/"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="accountsservice wayland"
+
+DEPEND="
+	virtual/libintl
+	x11-libs/gtk+:3
+	>=xfce-base/exo-0.12:=
+	>=xfce-base/garcon-0.6.4:=
+	>=xfce-base/libxfce4ui-4.14:=
+	>=xfce-base/libxfce4util-4.14:=
+	>=xfce-base/xfce4-panel-4.14:=
+	>=xfce-base/xfconf-4.14:=
+	accountsservice? (
+		>=sys-apps/accountsservice-0.6.45
+	)
+	wayland? (
+		>=gui-libs/gtk-layer-shell-0.7
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+# upstream does fancy stuff in other build types
+CMAKE_BUILD_TYPE=Debug
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_AS_NEEDED=OFF
+		-DENABLE_LINKER_OPTIMIZED_HASH_TABLES=OFF
+		-DENABLE_DEVELOPER_MODE=OFF
+		-DENABLE_LINK_TIME_OPTIMIZATION=OFF
+		-DENABLE_ACCOUNTS_SERVICE=$(usex accountsservice)
+		-DENABLE_GTK_LAYER_SHELL=$(usex wayland)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}