games-emulation/mgba: add 0.10.0

ebuild updates:
- require sqlite with USE=gui and enable by default (segfaults without)
- enable opengl by default for non-desktop profiles, sdl build is not
  very useful without this or gles2
- check for gles2 on libsdl2 too (gles3 only seem to work with Qt)
- patch to disable Qt's updater, not only is it not needed but it has
  incompatible pointer type issues (broken with clang16)
- drop || ( gui sdl ) required use (allows library-only build,
  albeit no in-tree consumers for this currently)
- change subslot to 0/$(ver_cut 1-2) rather than 0/10 (matches SONAME).

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

games-emulation/mgba/Manifest

@@ -1 +1,2 @@
+DIST mgba-0.10.0.tar.gz 14302653 BLAKE2B 0ebfa8a3de5db61452f070116fcf2d6312ce96f5d08b1b1e70ba8f7e50235fecff2a0f6a5a32860b7e95e55a6ab5bbf2227d483bad7eb25d6c7e471424bcf0dd SHA512 05939f94bc00906d999b955091e8e8059cc13a5b822048f6e002062c2e74069337d947d2cde2f8c1be96e3353a361743d752811c214fa9da31ed6a4893b4d7e8
 DIST mgba-0.9.3.tar.gz 12763090 BLAKE2B 7d9ff6fc7bdff5d734540b74893a888d400b4bb6e1ce5b3b2a856239db8798ac76b8535dc770330d0451e2568a6d402558eeef27d643c0d5d3454441f45cf09b SHA512 da65b3c7ec32d732163f129c4fd38949ae2da2980beb3257bf6def5e35534a27b6d30309bb3c9a8d651642f99e1a45db7a8577c8dbf5472153d4551167471b3a

games-emulation/mgba/files/mgba-0.10.0-optional-updater.patch

@@ -0,0 +1,7 @@
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -980,3 +980,3 @@
+ if(BUILD_QT AND (WIN32 OR APPLE OR CMAKE_SYSTEM_NAME STREQUAL "Linux"))
+-	set(BUILD_UPDATER ON)
++	set(BUILD_UPDATER ON CACHE BOOL "")
+ endif()

games-emulation/mgba/mgba-0.10.0.ebuild

@@ -0,0 +1,106 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{3..4} )
+inherit cmake lua-single xdg
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
+else
+	SRC_URI="https://github.com/mgba-emu/mgba/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Game Boy Advance Emulator"
+HOMEPAGE="https://mgba.io/"
+
+LICENSE="MPL-2.0 BSD LGPL-2.1+ public-domain discord? ( MIT )"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="debug discord elf ffmpeg gles2 gles3 gui libretro lua +opengl +sdl +sqlite test"
+REQUIRED_USE="
+	gui? ( || ( gles2 gles3 opengl ) sqlite )
+	lua? ( ${LUA_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	media-libs/libpng:=
+	sys-libs/zlib:=[minizip]
+	debug? ( dev-libs/libedit )
+	elf? ( dev-libs/elfutils )
+	ffmpeg? ( media-video/ffmpeg:= )
+	gles2? ( media-libs/libglvnd )
+	gles3? ( media-libs/libglvnd )
+	lua? ( ${LUA_DEPS} )
+	opengl? ( media-libs/libglvnd )
+	gui? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( media-libs/libsdl2[sound,joystick,gles2?,opengl?,video] )
+	sqlite? ( dev-db/sqlite:3 )"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )"
+BDEPEND="lua? ( virtual/pkgconfig )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.10.0-optional-updater.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CINEMA=$(usex test)
+		-DBUILD_GL=$(usex opengl)
+		-DBUILD_GLES2=$(usex gles2)
+		-DBUILD_GLES3=$(usex gles3)
+		-DBUILD_LIBRETRO=$(usex libretro)
+		-DBUILD_QT=$(usex gui)
+		-DBUILD_SDL=$(usex sdl) # also used for gamepads in QT build
+		-DBUILD_SUITE=$(usex test)
+		-DBUILD_UPDATER=OFF
+		-DENABLE_SCRIPTING=$(usex lua)
+		-DMARKDOWN=OFF #752048
+		-DUSE_DEBUGGERS=$(usex debug)
+		-DUSE_DISCORD_RPC=$(usex discord)
+		-DUSE_EDITLINE=$(usex debug)
+		-DUSE_ELF=$(usex elf)
+		-DUSE_EPOXY=OFF
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_GDB_STUB=$(usex debug)
+		-DUSE_LIBZIP=OFF
+		-DUSE_LZMA=ON
+		-DUSE_MINIZIP=ON
+		-DUSE_PNG=ON
+		-DUSE_SQLITE3=$(usex sqlite)
+		-DUSE_ZLIB=ON
+		$(usev libretro -DLIBRETRO_LIBDIR="${EPREFIX}"/usr/$(get_libdir)/libretro)
+	)
+	use lua && mycmakeargs+=( -DUSE_LUA=$(ver_cut 1-2 $(lua_get_version)) )
+
+	cmake_src_configure
+}
+
+src_test() {
+	# CMakeLists.txt forces SKIP_RPATH=ON when PREFIX=/usr
+	local -x LD_LIBRARY_PATH=${BUILD_DIR}:${LD_LIBRARY_PATH}
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	use !test || rm "${ED}"/usr/bin/mgba-cinema || die
+
+	rm -r "${ED}"/usr/share/doc/${PF}/{LICENSE,licenses} || die
+}