mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
dev-python/pbr: Bump to 7.1.3
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST pbr-7.1.2.tar.gz 140252 BLAKE2B 7e1a2718661bc18c5220ac7ab82cb2f9faebe1941e3d7bedbc7720aa981856fe318c2c35dfd943e14e13c7280324901beacd72adbbac5b099926afa64247ed62 SHA512 deac07ad91cfdd898f5a40b101b3e54e949f5f2c81c55c0eb119b3f7168a3ffb072ce4e898b877c6d40db73fe29f6b81f553f9ce494a947f62b6912510245865
|
||||
DIST pbr-7.1.3.tar.gz 140100 BLAKE2B fcaad86bc593bc25b0b798410419abd25b0e7677c66a41bc69c433ed5e99b1c2a473ad1bb4fb1d2a33386028d5befb00252626ab3ba5366248ef2e0ef5594efc SHA512 d0a257f96fa8381656fc1c468adfaa6da7078f17e462acd9318b84b9e52011c8553eb9cfc7f4c241edcc3cf975da585656be837784d16c5f9a013430b61c2ffb
|
||||
|
||||
@@ -0,0 +1,62 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=standalone
|
||||
PYTHON_COMPAT=( python3_{12..15} )
|
||||
PYTHON_REQ_USE="threads(+)"
|
||||
|
||||
inherit distutils-r1 pypi
|
||||
|
||||
DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
|
||||
HOMEPAGE="
|
||||
https://opendev.org/openstack/pbr/
|
||||
https://github.com/openstack/pbr/
|
||||
https://pypi.org/project/pbr/
|
||||
"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/setuptools-64.0.0[${PYTHON_USEDEP}]
|
||||
"
|
||||
|
||||
# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and
|
||||
# https://bugs.gentoo.org/show_bug.cgi?id=561038 docutils is needed for sphinx
|
||||
# exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848 stestr is run as
|
||||
# external tool.
|
||||
BDEPEND="
|
||||
${RDEPEND}
|
||||
test? (
|
||||
>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
|
||||
>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
|
||||
dev-vcs/git
|
||||
)
|
||||
"
|
||||
|
||||
distutils_enable_tests unittest
|
||||
|
||||
python_prepare_all() {
|
||||
# TODO: investigate
|
||||
sed -e 's:test_with_argument:_&:' \
|
||||
-e 's:test_wsgi_script_run:_&:' \
|
||||
-i pbr/tests/functional/test_wsgi_scripts.py || die
|
||||
# installs random packages via pip from the Internet
|
||||
rm pbr/tests/functional/test_pep517.py || die
|
||||
rm pbr/tests/functional/test_requirements.py || die
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_test() {
|
||||
cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
|
||||
eunittest -b
|
||||
}
|
||||
Reference in New Issue
Block a user