sci-chemistry/avogadro2: Add 1.90.0_p20180211 snapshot

Closes: https://bugs.gentoo.org/649864
Package-Manager: Portage-2.3.28, Repoman-2.3.9

sci-chemistry/avogadro2/Manifest

@@ -1 +1,2 @@
 DIST avogadro2-0.9.0.tar.gz 1096442 BLAKE2B b2c986b57fa5a9ea8876316f403bef55e9dd1f0a61d9320876935635952ef4e8443fc763a0f57595007e3a9c681d2fa083cf417b94e66b22dd188b05b6db8343 SHA512 bc780b1f45822ffc6cef82cf5fbe04cfbab035e553037959965eb0cad2c3f87e53bc71a574c7154cae5909377c74d14708550070c1794bdd5d83d738846b03ba
+DIST avogadro2-1.90.0_p20180211.tar.gz 1099312 BLAKE2B fbf8e2006c46114632587615b48ac130e45a46ce2859a9c34270714091bc8397d9d7a93c3166bf58833f100e3e40afd1962012e479a8f92ba8ff9078200d51c5 SHA512 db9b0983d2161df493138ddf18c5dbda54cf2f8b75ebc944f1f57dab0f1e2048582362e5f46a78b1610aba080aaac8a66d2b2b71db748e031ffde306d3609856

sci-chemistry/avogadro2/avogadro2-1.90.0_p20180211.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN=avogadroapp
+COMMIT=d5e1f827be7e9d1cc6755fd68a2b42b0b1d2ec32
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="Advanced molecule editor and visualizer 2"
+HOMEPAGE="https://www.openchemistry.org/"
+SRC_URI="https://github.com/OpenChemistry/${MY_PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD GPL-2+"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc rpc test vtk"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	>=sci-libs/avogadrolibs-${PV}[qt5,vtk?]
+	sci-libs/hdf5:=
+	rpc? ( sci-chemistry/molequeue )
+"
+DEPEND="${DEPEND}
+	dev-cpp/eigen:3
+	test? ( dev-qt/qttest:5 )
+"
+
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_PN}-${COMMIT}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed -e "/LICENSE/d" -i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DAvogadro_ENABLE_RPC=$(usex rpc)
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_VTK=$(usex vtk)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}