app-misc/votrify: Bump to v2

Now with friendly wrappers for Council 2019 election.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

app-misc/votrify/Manifest

@@ -1 +1,2 @@
 DIST votrify-1.tar.gz 6936 BLAKE2B 7c9a5668842c5b1783e5c8b2341d42aa21257b96a82210c16e44bee8f71b690c7dba5acf48a39beff0189106db1fe141ef1ec30d68f25573a19a53c12618d346 SHA512 14fdb4ee185d96f416b47df7b29175cebc6e003aca7c1faf927b258f7dbe39b7ed69c4defb25900c6856b6e9abde3b03a69ca02152755d8532708b6cfb7f51a0
+DIST votrify-2.tar.gz 9095 BLAKE2B 801c9ad89f93349ce6ad0d9421e9a968a511d9699454c91cc713dd3a133c4f87666de3bc3905041999a5090eb5794d6ceed89aabc997e6950d2b5a4b4bb185cc SHA512 8c3795520d6ee5d34c8aa649a24309e30da8843bcddbfc8ff0b822eab5529a621d9fa475dc6714a6de0ed1d229d3a949870666967448a23036d28af5e7da00ab

app-misc/votrify/votrify-2.ebuild

@@ -0,0 +1,51 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit python-single-r1
+
+DESCRIPTION="Tool for community verification of Gentoo elections"
+HOMEPAGE="https://github.com/mgorny/votrify"
+SRC_URI="https://github.com/mgorny/votrify/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="app-misc/gentoo-elections"
+
+src_configure() {
+	# update default location for election scripts
+	sed -i -e "s^os.path.dirname(__file__)^'${EPREFIX}/usr/lib'^" \
+		votrify-make-confirmation || die
+
+	python_fix_shebang votrify-{make,verify}-*
+}
+
+make_wrappers() {
+	local election=${1}
+
+	newbin - "votrify-${election}-make" \
+		< <(sed -e "s^@ELECTION@^${election}^" \
+			votrify-wrapper-make.bash.in || die)
+	newbin - "votrify-${election}-verify" \
+		< <(sed -e "s^@ELECTION@^${election}^" \
+			votrify-wrapper-verify.bash.in || die)
+}
+
+src_install() {
+	dobin votrify-{make,verify}-*
+	make_wrappers council-201906
+	einstalldocs
+}
+
+pkg_postinst() {
+	elog "In order to interactively create confirmation for Council 2019 election:"
+	elog "  votrify-council-201906-make"
+	elog
+	elog "In order to verify the results for Council 2019 election:"
+	elog "  votrify-council-201906-verify"
+}