dev-python/authlib: Bump to 1.9.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/authlib/Manifest

@@ -1 +1,2 @@
 DIST authlib-1.9.1.gh.tar.gz 388395 BLAKE2B 20579375edb0965c5ff6755eefcc43c69c35352f43db71be86087ef1c8a6b462dd477add868d55d332c7f3367f6ad330f916e1b495d87180ab89ec227657d006 SHA512 3f106f800a668c0f2f11fab6cbe56185975c5ad9a9509637055ca6d5528006c88c17dc6980bfc78cdda8e719c7823aee86c64dd3e939829f93ef250e0939809f
+DIST authlib-1.9.2.gh.tar.gz 389413 BLAKE2B a113bf35733b0bc1fd27cf0410a4fca951b124381ae742a88e8fd1e53ee5a3760e4ac82223a94186e4009020c5a6f66edfb1d26c34da763b6f60b49694bab979 SHA512 18ea8d9c58fb1f06fc9b206b9a9df603e201eef14fcb1fef5fcbe8fcdc87c8a190a30c65008322b9bfd4d39667d6518a4e8a44debb498af7c7d8be2932f5e237

dev-python/authlib/authlib-1.9.2.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients"
+HOMEPAGE="
+	https://authlib.org/
+	https://github.com/authlib/authlib/
+	https://pypi.org/project/Authlib/
+"
+# pypi source distribution excludes the tests
+SRC_URI="
+	https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="django test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cryptography-45.0.1[${PYTHON_USEDEP}]
+	>=dev-python/joserfc-1.6.8[${PYTHON_USEDEP}]
+	django? (
+		>=dev-python/django-3.2.9[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/cachelib[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/httpx2[${PYTHON_USEDEP}]
+		dev-python/joserfc[${PYTHON_USEDEP}]
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/starlette[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{asyncio,env} )
+# EPYTEST_XDIST makes tests flaky
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# convert from pycryptodomex to pycryptodome
+	sed -i -e 's:from Cryptodome:from Crypto:' \
+		authlib/jose/drafts/_jwe_enc_cryptodome.py || die
+}
+
+python_test() {
+	epytest tests/{core,jose,clients}
+
+	# TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded yet.
+	#epytest tests/django
+}