mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 00:48:18 -07:00
games-fps/urbanterror: version bump to 4.3.2_p20170915.
Package-Manager: Portage-2.3.10, Repoman-2.3.3 Closes: https://github.com/gentoo/gentoo/pull/5759
This commit is contained in:
Nils Freydank
committed by
Patrice Clement
Patrice Clement
parent
3ee9d48fff
commit
8f73dfd5fa
@@ -1,2 +1,3 @@
|
||||
DIST urbanterror-4.3.2_p20170426.tar.gz 10058308 SHA256 8009516332e1f77eae3681b436e099fdd42ffa55d2691694eedc0ca94b194878 SHA512 e8107ab44fdb40bc14a548239185905a01120bbe960b8713e5959df18330fd845761350c5e8e5efd5fbfec10ad62ff9fef68420406cc4cfbe2af69ee66eff1f3 WHIRLPOOL 6aac15e44b0695501195ae172133f4b6788b9dffa5442af20d11626ad27ffd597c7f070c0fb95b0e0e8b8b3d6cf0e1bfc40b0a16abaa27c8f932ee90f19a1824
|
||||
DIST urbanterror-4.3.2_p20170713.tar.gz 9984763 SHA256 cf1784a3bd00451fe1bda3267235ea3eee93da65880f15fd13c07681952b4859 SHA512 09fd2232c3cbdde001b8d037f2667a55a584378615f2da10c6815797748028f36b75c899ca4fd1d7d97a33f4b3ddbaa4d271b36b5eabf3bf9e81852ef15864a4 WHIRLPOOL 2bed79adc1dc338d74212263105c03bad51391f8c9e9e543ad54f6d6006cea4a8ebfc0e601400338b941d799dc0f642f71478dc68ad84a50718043f06f042290
|
||||
DIST urbanterror-4.3.2_p20170915.tar.gz 10061394 SHA256 fe37df609d763247a0bfaa7dedb33ca45a8aa523467b16f1a585ca8a08b03078 SHA512 d22bc3a0d8d191f797f5b1e7a0671424ca6dafbe5a3bd7fbfcd0e7249b9b4b6e790a64cdf7c93690d032b38f92aee703e9e302701084703d7a79d8f60cc2433e WHIRLPOOL 912201a55822dcf8423f77023f01882339739984dc9e9bdb5dca55763271c56158b47fd137da83d6e56c7625e49df8b5fc5299af646e91104e1f53cad9a50fcb
|
||||
|
||||
152
games-fps/urbanterror/urbanterror-4.3.2_p20170915.ebuild
Normal file
152
games-fps/urbanterror/urbanterror-4.3.2_p20170915.ebuild
Normal file
@@ -0,0 +1,152 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="6"
|
||||
inherit flag-o-matic gnome2-utils
|
||||
|
||||
DESCRIPTION="Hollywood tactical shooter based on the ioquake3 engine"
|
||||
HOMEPAGE="http://urbanterror.info https://github.com/mickael9/ioq3"
|
||||
|
||||
if [[ ${PV} == "9999" ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/mickael9/ioq3.git"
|
||||
EGIT_BRANCH="urt"
|
||||
else
|
||||
COMMIT_ID="0b3e62a00bd05d337f2ab6dad2cdb311a5d76464"
|
||||
SRC_URI="https://github.com/mickael9/ioq3/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
|
||||
S="${WORKDIR}/ioq3-${COMMIT_ID}"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
|
||||
fi
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
IUSE="+altgamma +client +curl debug mumble openal +opus server voip vorbis"
|
||||
REQUIRED_USE=" || ( client server )"
|
||||
|
||||
PATCHES=( "${FILESDIR}"/${PN}-4.3-respect_CFLAGS.patch )
|
||||
|
||||
RDEPEND="
|
||||
client? (
|
||||
media-libs/libsdl2[X,sound,joystick,opengl,video]
|
||||
mumble? ( media-sound/mumble )
|
||||
openal? ( media-libs/openal )
|
||||
opus? ( media-libs/opusfile )
|
||||
vorbis? (
|
||||
media-libs/libogg
|
||||
media-libs/libvorbis
|
||||
)
|
||||
)
|
||||
curl? ( net-misc/curl )
|
||||
~games-fps/urbanterror-data-4.3.2
|
||||
sys-libs/zlib[minizip]
|
||||
virtual/jpeg:0
|
||||
"
|
||||
|
||||
DEPEND="${RDEPEND}"
|
||||
|
||||
pkg_pretend() {
|
||||
if use client; then
|
||||
if ! use openal && ! use opus && ! use vorbis; then
|
||||
ewarn
|
||||
ewarn "No sound implementation selected. Enable 'openal', 'opus' or 'vorbis' USE flag to get sound!"
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
buildit() { use $1 && echo 1 || echo 0 ; }
|
||||
nobuildit() { use $1 && echo 0 || echo 1 ; }
|
||||
|
||||
# Workaround for used zlib macro, wrt bug #44951
|
||||
append-flags "-DOF=_Z_OF"
|
||||
|
||||
emake \
|
||||
ARCH=$(usex amd64 "x86_64" "i386") \
|
||||
DEFAULT_BASEDIR="/usr/share/urbanterror" \
|
||||
BUILD_CLIENT=$(buildit client) \
|
||||
BUILD_SERVER=$(buildit server) \
|
||||
BUILD_BASEGAME=1 \
|
||||
BUILD_MISSIONPACK=0 \
|
||||
BUILD_GAME_SO=0 \
|
||||
BUILD_GAME_QVM=0 \
|
||||
BUILD_STANDALONE=1 \
|
||||
SERVERBIN="Quake3-UrT-Ded" \
|
||||
CLIENTBIN="Quake3-UrT" \
|
||||
USE_RENDERER_DLOPEN=0 \
|
||||
USE_YACC=0 \
|
||||
BASEGAME="q3ut4"\
|
||||
BASEGAME_CFLAGS="${CFLAGS}" \
|
||||
USE_OPENAL=$(buildit openal) \
|
||||
USE_OPENAL_DLOPEN=$(buildit openal) \
|
||||
USE_CURL=$(buildit curl) \
|
||||
USE_CURL_DLOPEN=$(buildit curl) \
|
||||
USE_CODEC_VORBIS=$(buildit vorbis) \
|
||||
USE_CODEC_OPUS=$(buildit opus) \
|
||||
USE_MUMBLE=$(buildit mumble) \
|
||||
USE_VOIP=$(buildit voip) \
|
||||
USE_INTERNAL_LIBS=0 \
|
||||
USE_LOCAL_HEADERS=0 \
|
||||
USE_ALTGAMMA=$(buildit altgamma)
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local my_arch=$(usex amd64 "x86_64" "i386")
|
||||
|
||||
# docs from ioq3, not from UrbanTerror ZIP file
|
||||
dodoc ChangeLog README.md README.ioq3.md md4-readme.txt
|
||||
|
||||
if use client; then
|
||||
newbin build/$(usex debug "debug" "release")-linux-${my_arch}/Quake3-UrT.${my_arch} ${PN}
|
||||
# Shooter as defined in https://specifications.freedesktop.org/menu-spec/latest/apas02.html
|
||||
make_desktop_entry ${PN} "UrbanTerror" ${PN}
|
||||
fi
|
||||
|
||||
if use server && ! use client; then
|
||||
# dedicated server only
|
||||
newbin build/$(usex debug "debug" "release")-linux-${my_arch}/Quake3-UrT-Ded.${my_arch} ${PN}-ded
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
use client && gnome2_icon_savelist
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use client && gnome2_icon_cache_update
|
||||
|
||||
if [[ -z "${REPLACING_VERSIONS}" ]]; then
|
||||
# This is a new installation
|
||||
if use openal; then
|
||||
elog ""
|
||||
elog "You might need to set:"
|
||||
elog " seta s_useopenal \"1\""
|
||||
elog "in your ~/.q3a/q3ut4/q3config.cfg for openal to work."
|
||||
fi
|
||||
|
||||
if use altgamma; then
|
||||
elog ""
|
||||
elog "You might need to set:"
|
||||
elog " seta r_altgamma \"1\""
|
||||
elog "in your ~/.q3a/q3ut4/q3config.cfg for altgamma to work."
|
||||
fi
|
||||
|
||||
if ! use altgamma; then
|
||||
elog ""
|
||||
elog "If you are using a modesetting graphics driver you might"
|
||||
elog "consider setting USE=\"altgamma\"."
|
||||
elog "For details take a look at:"
|
||||
elog "https://bugs.freedesktop.org/show_bug.cgi?id=27222"
|
||||
fi
|
||||
if ! use client; then
|
||||
elog ""
|
||||
elog "You disabled client support. You won't be able to connect"
|
||||
elog "to any servers and play. If you want to do so, enable"
|
||||
elog "USE=\"client\"."
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use client && gnome2_icon_cache_update
|
||||
}
|
||||
Reference in New Issue
Block a user