dev-python/jsonschema-path: Bump to 0.4.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/jsonschema-path/Manifest

@@ -1,2 +1,3 @@
 DIST jsonschema-path-0.3.4.gh.tar.gz 40126 BLAKE2B cc7884ab41a0cdcfbd292831f9ed2a03f82af30f4482499c7940633741560228df59c4157457e8c44c57fb73f0f6142f10ad23d36f444fea71a84cf6309d953d SHA512 85b791a374d61bedf66a0ca44b6906ec74f02ffe991c1cb220267c85c0e7b493375d712d7ca0828681c9c15f170bc29d4b808b00778895fb13f1f7ff3cdf2a9c
 DIST jsonschema-path-0.4.0b8.gh.tar.gz 59277 BLAKE2B 7b3fb5cc410f26b5e4960b300851194a887e27e50c05ca5818e7cd1e118f6657a55841092f2cdac130f166eddeca81e48d06fb25c60a5380859581531d9c05bb SHA512 719b57f6581e540d152863365ab85f7c9aafb0ab79880e6ccfca462f2d64892636276d741acc09662cdba242ce1e54833a42bd38048ce6c7299d9609715f9bac
+DIST jsonschema-path-0.4.1.gh.tar.gz 59800 BLAKE2B 8e049c88d73772216f76975048f66b55bacf1be680a4ea79926db6f3a76012ca263bf348bff46065a1e9eac8bcd82c159d7230592a8b754bb9fd2d5e64dea04c SHA512 92f5c6a8102e19b0df4b24118db8270f7de68f62804a59c55a0bed21697187c5f3ee4ae18c77ca9ffaf5de8f3611eecfc789b96d906735ed0d0c4552642fe3cd

dev-python/jsonschema-path/jsonschema-path-0.4.1.ebuild

@@ -0,0 +1,50 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="JSONSchema Spec with object-oriented paths"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema-path/
+	https://github.com/p1c2u/jsonschema-path/
+"
+SRC_URI="
+	https://github.com/p1c2u/jsonschema-path/archive/${PV/_beta/b}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+if [[ ${PV} != *_beta* ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+RDEPEND="
+	>=dev-python/pathable-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/referencing-0.28.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	# remove random pins
+	sed -i -e 's:\^:>=:' -e 's:<[0-9.]\+:*:' pyproject.toml || die
+	distutils-r1_src_prepare
+}