dev-python/build: Bump to 1.6.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/build/Manifest

@@ -1,2 +1,3 @@
 DIST build-1.5.1.gh.tar.gz 119395 BLAKE2B bcf8d2e9abb06e8bda1e39667a3e29d562821fb2015ddcb6569de82e6a790c16f5a429a8cc2c58685287666d7759e462426168cbd65c28709fb967f713542e34 SHA512 d1ef87a2559ff29c0de4436ca2b9ed4e1f27660f81673afd40318586ff8fee581dc85936a00bf4b1afef8160746c0378a6a99c6c6887d64772450adc8387b2a3
 DIST build-1.6.0.gh.tar.gz 121558 BLAKE2B e53a281ce4b19d9ff192f8d99d310c6619bf2741794b695828ddbb2e326b2cc7c3c93ec05ffd5713a8b0a592c33392e931371dffd713eb0b6ef249bf7fde4d20 SHA512 42105517da9e685f64cf65da082251a77a8a82048d15f7ac517dd1d80819c4ed9dacbc2ec92ee9561ae276de03c65afd8bb1c7ae03f03748de09af2d3820bcd0
+DIST build-1.6.1.gh.tar.gz 121156 BLAKE2B b7b96f5c4a2de6f57f59aa647a8eb35c2df3a47c12aa9a186d9cdb05bb50c8009955ed3d59c22f7e89fc3119445459fe66c4040b61712f8ea8da504a4453d0a5 SHA512 83a3a49fc92bdd717ad64fe3772489ba72c7f362484e7bb9baf7f5a68a167c876abe1222778691599e40f021c993223b9336437bcfab752d754b110651e2e11b

dev-python/build/build-1.6.1.ebuild

@@ -0,0 +1,78 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_TESTED=( python3_{12..15} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_{14..15}t )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="A simple, correct PEP517 package builder"
+HOMEPAGE="
+	https://pypi.org/project/build/
+	https://github.com/pypa/build/
+"
+SRC_URI="
+	https://github.com/pypa/build/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test test-rust"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			>=dev-python/filelock-3.20.1[${PYTHON_USEDEP}]
+			>=dev-python/pip-22.3[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-mock-2[${PYTHON_USEDEP}]
+			>=dev-python/pytest-rerunfailures-9.1[${PYTHON_USEDEP}]
+			>=dev-python/pytest-xdist-1.34[${PYTHON_USEDEP}]
+			>=dev-python/setuptools-56.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.36.1[${PYTHON_USEDEP}]
+			>=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
+			test-rust? (
+				!s390? ( !sparc? ( >=dev-python/uv-0.1.18 ) )
+			)
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+python_test() {
+	if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# broken by uv being installed outside venv
+		tests/test_env.py::test_external_uv_detection_success
+		# Internet
+		'tests/test_main.py::test_main_sdist_input_end_to_end[False]'
+	)
+
+	if ! has_version "dev-python/uv"; then
+		EPYTEST_DESELECT+=(
+			tests/test_env.py::test_uv_impl_install_cmd_well_formed
+			'tests/test_env.py::test_venv_creation[uv-venv+uv-None]'
+		)
+	fi
+
+	local EPYTEST_PLUGINS=( pytest-{mock,rerunfailures} )
+	local EPYTEST_XDIST=1
+	epytest -m "not network"
+}