app-misc/libdatovka: new package dependency for app-misc/datovka

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Amy Liffey <amynka@gentoo.org>

app-misc/libdatovka/Manifest

@@ -0,0 +1 @@
+DIST libdatovka-0.1.2.tar.xz 672348 BLAKE2B 34fd0e3651fd468c96c99d261b199cb25b5d6ac46ae19f96b29c62037acdd7a0a053a5098f317da2dc31b27df7879839163dfe1a109877ed61880723b429a626 SHA512 2c9bf9f7a2166582d8757b1811031cc3501872baad1ec901799253036bbf5e33a059cd3310e6798e4e248b41c92f4775ab3fad90a97648eee5afece8203bc827

app-misc/libdatovka/libdatovka-0.1.2.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Client library for accessing ISDS SOAP services"
+HOMEPAGE="https://www.datovka.cz/cs/pages/libdatovka.html"
+SRC_URI="https://secure.nic.cz/files/datove_schranky/${PN}/${P}.tar.xz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="+curl debug doc nls openssl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/libxml2
+	curl? ( net-misc/curl[ssl] )
+	doc? (
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxslt
+	)
+	openssl? ( dev-libs/openssl:= )
+	!openssl? (
+		app-crypt/gnupg
+		app-crypt/gpgme
+		dev-libs/libgcrypt:=
+	)"
+DEPEND="${RDEPEND}
+	test? ( net-libs/gnutls )"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	local myeconfargs=(
+		--disable-fatalwarnings
+		--disable-static
+		$(use_with curl libcurl)
+		$(use_enable curl curlreauthorizationbug)
+		$(use_enable doc)
+		$(use_enable debug)
+		$(use_enable nls)
+		$(use_enable openssl openssl-backend)
+		$(use_enable test)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}

app-misc/libdatovka/metadata.xml

@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>amynka@gentoo.org</email>
+	</maintainer>
+	<use>
+		<flag name="openssl">Use openssl backend</flag>
+	</use>
+</pkgmetadata>