media-gfx/gnome-photos: bump to 3.24.6, fixes "Empty Trash" button

Package-Manager: Portage-2.3.28, Repoman-2.3.9

media-gfx/gnome-photos/Manifest

@@ -1 +1,2 @@
 DIST gnome-photos-3.24.5.tar.xz 985864 BLAKE2B d5e7dd48a6f81c9ca6efa7dcb2b17fdeb781070d1789514098b8cf30bcd12eba145e57e584f42f66286579ad40ef31f370c471abaab30ba684bada9878afc3c4 SHA512 8dcdb9962a55d6e2e9aa28ef86dcc9100f80fa9739763cea1475052379050a23428e09e8416ed75b9a9b1c85a9bc27d94a75faeefde3d546195c21f04f85379d
+DIST gnome-photos-3.24.6.tar.xz 986200 BLAKE2B 656737326f594958ea1cc956f85e50c7eaebc227491d95342acab9a1fa0e3c5c109efe932cd0465e48ada62beab238e6eef0e01033b145de72a1fb64ce2f3c89 SHA512 47fd858b643fe0bca9a4801d43bd7eb181db08d7e09941a60a134247df97b0e900cd062efef70da5161a9fceb1d33b998b87ad5eca0a5937a10c4e06b908de22

media-gfx/gnome-photos/gnome-photos-3.24.6.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Access, organize and share your photos on GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Photos"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flickr test upnp-av"
+
+COMMON_DEPEND="
+	>=app-misc/tracker-1:=[miner-fs]
+	>=dev-libs/glib-2.44:2
+	gnome-base/gsettings-desktop-schemas
+	>=dev-libs/libgdata-0.15.2:0=[gnome-online-accounts]
+	media-libs/babl
+	>=media-libs/gegl-0.3.14:0.3[cairo,jpeg2k,raw]
+	media-libs/gexiv2
+	>=media-libs/grilo-0.3.0:0.3=
+	>=media-libs/libpng-1.6:0=
+	>=net-libs/gnome-online-accounts-3.8:=
+	>=net-libs/libgfbgraph-0.2.1:0.2
+	sci-geosciences/geocode-glib
+	>=x11-libs/cairo-1.14
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22.15:3
+"
+# gnome-online-miners is also used for google, facebook, DLNA - not only flickr
+# but out of all the grilo-plugins, only upnp-av and flickr get used, which have USE flags here,
+# so don't pull it always, but only if either USE flag is enabled
+RDEPEND="${COMMON_DEPEND}
+	net-misc/gnome-online-miners[flickr?]
+	upnp-av? ( media-plugins/grilo-plugins:0.3[upnp-av] )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr] )
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# XXX: how to deal with rdtscp support, x86intrin
+	gnome2_src_configure \
+		$(use_enable test dogtail)
+}
+
+src_test() {
+	virtx emake check
+}