sys-auth/google-authenticator: Version bump to 1.05

Package-Manager: Portage-2.3.24, Repoman-2.3.6

sys-auth/google-authenticator/Manifest

@@ -1 +1,2 @@
 DIST google-authenticator-1.04.tar.gz 54019 BLAKE2B 06afb1be1ceabb68bb7ba94921af415fe1dfd68b3b1ed75b58b3c5a58901ec482ae11063f487db0a7032868e833644022335ad9844f54734c2ad78c514f255a8 SHA512 e4b8ad74301312e17edd0a7f25257086fd805c8d5215b06b71d96e9a64a71b2c87d0c5a532d9eca21d6d67e30c02c2c2c77dbd338a2f49af25c32dcd355ee98e
+DIST google-authenticator-1.05.tar.gz 57778 BLAKE2B c31d7929e2aacffc159ee5384f6f31498585819b848f4f8b026519cf2f2fc566b8533e007844c64d348f1cf423a7175b3221f879c5c1ead360c4f1b3acea57ed SHA512 d97b26c6181dbce0612628484db37b1bf61e984fb2fb3d4974d04038e564404aa17415368dba524f0d17d96ec8d57ae4129b27f0c672d849d16ef03941d87996

sys-auth/google-authenticator/google-authenticator-1.05.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/google/google-authenticator-libpam.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/google/google-authenticator-libpam/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	S="${WORKDIR}/google-authenticator-libpam-${PV}"
+fi
+
+DESCRIPTION="PAM Module for two step verification via mobile platform"
+HOMEPAGE="https://github.com/google/google-authenticator-libpam"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="virtual/pam"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# We might want to use getpam_mod_dir from pam eclass,
+	# but the build already appends "/security" for us.
+	econf --libdir="/$(get_libdir)"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		elog "For further information see"
+		elog "https://wiki.gentoo.org/wiki/Google_Authenticator"
+		elog ""
+		elog "If you want support for QR-Codes, install media-gfx/qrencode."
+	fi
+}